如何 'silently' 从 Linux 上的终端获取用户输入？

Question

我需要让用户输入跳过其中的第二个辅音。所以每个第二个辅音 应该 而不是 被打印出来 （而不是在某些过程中按 Enter 后才被删除）。

老师给我布置了一个汇编语言的任务。目前我在 Linux 上使用 NASM 并希望坚持下去。

问题是我需要 'overload' 用户输入中断，并且在其中我应该能够处理该输入（跳过第二个辅音）。我在网上搜索过，没有找到任何合适的答案。不是如何在缓冲和打印之前 'catch' 用户输入，也不是读取单个字符而不在终端打印它的方法。

我想看一个替换（或修改）标准输入中断系统调用的例子。那将是最理想的情况。

第二种选择是制作您自己的 'handler' 类型，一个一个地获取每个字符而不回显它，而不是自己处理退格键和回车之类的事情。就像 Windows C 中的 getch() 一样。（或 0x16 BIOS 中断）。

Answer 1

这是我用来检索单个击键的示例。请记住，功能键、箭头和其他功能，如 HOME、PGDN 等 return 超过一个字节，因此我最多读取 8 个字节，这样输入缓冲区中剩下的内容就不会成为下一个工件写。这个片段被设计成一个响应系统，比如：

Continue [Y/N]

调用进程将读取 AL 中的 returned 字符。如果它是 0x1b (27 dec / ESC) 那么我们知道它是扩展键之一。例如，F1 将在 EAX 中 return 0x504f1b。

USE64

      sys_read      equ      0
      sys_write     equ      1
      sys_ioctl     equ     16

      %define      ICANON      2
      %define        ECHO      8
      %define      TCGETS      0x5401
      %define      TCPUTS      0X5402

            section    .text
    ; =============================================================================
    ; Accept a single key press from operator and return the result that may be
    ; up to 5 bytes in length.

    ;    LEAVE: RAX = Byte[s] returned by SYS_READ
    ; -----------------------------------------------------------------------------

      %define   c_lflag     rdx + 12
      %define      keys     rbp +  8
      %define      MASK     ICANON | ECHO

      STK_SIZE  equ 56              ; Room for 36 byte termios structure

      QueryKey:

            xor     eax, eax
            push    rax             ; This is where result will be stored.

            push    rbp
            mov     rbp, rsp
            sub     rsp, STK_SIZE

            push    r11             ; Modified by SYSCALL
            push    rbx
            push    rdx
            push    rcx
            push    rdi
            push    rsi             ; With size of 56, stack is now QWORD aligned

            mov     edi, eax            ; Equivalent to setting EDI to STDIN
            mov     esi, TCGETS
            lea     rdx, [rbp-STK_SIZE] ; Points to TERMIOS buffer on stack
            mov      al, sys_ioctl
            syscall

            lea     rbx, [c_lflag]
            and     byte [rbx], ~(MASK)
            inc     esi                 ; RSI = TCPUTS
            push    rsi
            mov      al, sys_ioctl
            push    rax
            syscall

       ; Wait for keypress from operator.

            lea     rsi, [keys]         ; Set buffer for input
            push    rdx
            mov     edx, 8              ; Read QWORD bytes max
            mov      al, sys_read
            syscall

NOTE: The code you need could go here

            pop     rdx                 ; Points back to TERMIOS
            pop     rax
            pop     rsi                 ; TCPUTS again
            or      byte [rbx], MASK
            syscall

            pop     rsi
            pop     rdi
            pop     rcx
            pop     rdx
            pop     rbx
            pop     r11

            leave
            pop        rax              ; Return up to 8 characters
            ret

如何 'silently' 从 Linux 上的终端获取用户输入？

How to 'silently' get user input from a terminal on Linux?

linux

assembly

input

nasm

tty