unity 2019中Unity3d标准曲面粒子流着色器错误

Question

我一直在尝试从 unity 的网站制作着色器示例以在 unity3d 2019 中编译。

Shader "Custom/test" {
Properties {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Albedo (RGB)", 2D) = "white" {}
    _Glossiness ("Smoothness", Range(0,1)) = 0.5
    _Metallic ("Metallic", Range(0,1)) = 0.0
}
SubShader {
    Tags {"Queue"="Transparent" "RenderType"="Transparent"}
    Blend SrcAlpha OneMinusSrcAlpha
    ZWrite off
    LOD 200

    CGPROGRAM
    // Physically based Standard lighting model, and enable shadows on all light types
    #pragma surface surf Standard alpha vertex:vert

    // Use shader model 3.0 target, to get nicer looking lighting
    #pragma target 3.0

    sampler2D _MainTex;

     struct appdata_particles {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
        float4 color : COLOR;
        float4 texcoords : TEXCOORD0;
        float texcoordBlend : TEXCOORD1;
        };


    struct Input {
        float2 uv_MainTex;
        float2 texcoord1;
        float blend;
        float4 color;
    };


    void vert(inout appdata_particles v, out Input o) {
        UNITY_INITIALIZE_OUTPUT(Input,o);
        o.uv_MainTex = v.texcoords.xy;
        o.texcoord1 = v.texcoords.zw;
        o.blend = v.texcoordBlend;
        o.color = v.color;
      }


    half _Glossiness;
    half _Metallic;
    fixed4 _Color;


    void surf (Input IN, inout SurfaceOutputStandard o) {
        fixed4 colA = tex2D(_MainTex, IN.uv_MainTex);
        fixed4 colB = tex2D(_MainTex, IN.texcoord1);
        fixed4 c = 2.0f * IN.color * lerp(colA, colB, IN.blend) * _Color;

        o.Albedo = c.rgb;
        // Metallic and smoothness come from slider variables
        o.Metallic = _Metallic;
        o.Smoothness = _Glossiness;
        o.Alpha = c.a;
    }
    ENDCG
}
FallBack "Diffuse"
}

但是编译报错： 'Custom/test' 中的着色器错误：第 157 行的无效下标 'texcoord'（在 d3d11 上）

我怀疑制作示例的 unity 2017 和 unity 2019 之间存在差异，但我无法弄清楚问题出在哪里。

Answer 1

设法弄明白了：

Shader "Custom/StandardTransparentQueue" {
Properties {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Albedo (RGB)", 2D) = "white" {}
    _Glossiness ("Smoothness", Range(0,1)) = 0.5
    _Metallic ("Metallic", Range(0,1)) = 0.0
}
SubShader {
    Tags {"Queue"="Transparent" "RenderType"="Transparent"}
    Blend SrcAlpha OneMinusSrcAlpha
    ZWrite off
    LOD 200

    CGPROGRAM
    // Physically based Standard lighting model, and enable shadows on all light types
    #pragma surface surf Standard alpha vertex:vert

    // Use shader model 3.0 target, to get nicer looking lighting
    #pragma target 3.0

    sampler2D _MainTex;

     struct appdata_particles {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
        float4 color : COLOR;
        float4 texcoords : TEXCOORD0;
        float texcoordBlend : TEXCOORD1;
        };


    struct Input {
        float2 texcoord;
        float2 texcoord1;
        float blend;
        float4 color;
    };


    void vert(inout appdata_particles v, out Input o) {
        UNITY_INITIALIZE_OUTPUT(Input,o);
        o.texcoord = v.texcoords.xy;
        o.texcoord1 = v.texcoords.zw;
        o.blend = v.texcoordBlend;
        o.color = v.color;
      }


    half _Glossiness;
    half _Metallic;
    fixed4 _Color;


    void surf (Input IN, inout SurfaceOutputStandard o) {
        fixed4 colA = tex2D(_MainTex, IN.texcoord);
        fixed4 colB = tex2D(_MainTex, IN.texcoord1);
        fixed4 c = 2.0f * IN.color * lerp(colA, colB, IN.blend) * _Color;

        o.Albedo = c.rgb;
        // Metallic and smoothness come from slider variables
        o.Metallic = _Metallic;
        o.Smoothness = _Glossiness;
        o.Alpha = c.a;
    }
    ENDCG
}
FallBack "Diffuse"
}

在 unity 2019 中，它期望 texcoord 成为输入结构的成员，而不是 uv_MainTex.

希望对其他人有帮助:)

unity 2019中Unity3d标准曲面粒子流着色器错误

Unity3d standard surface particle stream shader error in unity 2019

shader

particles

unity3d