如何对齐 Windows Media Player 控件以适合父级 window？

Question

我有一个 Windows Media Player ActiveX 控件。我希望它与其父 TPanel.

对齐

问题是无论我尝试什么，WMP 控件总是设置为其初始大小，无法调整它的大小。

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, XpMan, ExtCtrls, WMPLib_TLB;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
  public
    Panel: TPanel;
    MP: TWindowsMediaPlayer;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Width := 450;
  Height := 260;

  Panel := TPanel.Create(Self);
  Panel.Parent := Self;
  Panel.Align := alClient;


  MP := TWindowsMediaPlayer.Create(Self);
  // MP.stretchToFit := True;
  MP.Parent := Panel;
  MP.Align := alClient;
  MP.URL := 'https://www.w3schools.com/html/mov_bbb.mp4';
end;

当您打开窗体时，WMP 控件看起来不错：

但是当您调整窗体大小时，WMP 控件不会与父面板对齐：

这实际上是我尝试放大时看到的效果：

如何使 WMP 控件按预期运行？

我试过很多愚蠢的事情，比如：

procedure TForm1.FormResize(Sender: TObject);
begin
  if not Assigned(MP) then Exit;
  MP.Width := Panel.ClientWidth;
  MP.Height := Panel.ClientHeight;
  Panel.Realign;
end;

但是没有任何效果！

Answer 1

这是 OleCtrl 中 Delphi 7 TOleControl.SetBounds 中的错误。它已在较新版本中修复。

procedure TOleControl.SetBounds(ALeft, ATop, AWidth, AHeight: Integer);
var
  LRect: TRect;
begin
  if ((AWidth <> Width) and (Width > 0)) or ((AHeight <> Height) and (Height > 0)) then
  begin
    if (FMiscStatus and OLEMISC_INVISIBLEATRUNTIME <> 0) or
      ((FOleObject.SetExtent(DVASPECT_CONTENT, Point(
        MulDiv(AWidth, 2540, Screen.PixelsPerInch),
        MulDiv(AHeight, 2540, Screen.PixelsPerInch))) <> S_OK)) then
    begin
      AWidth := Width;
      AHeight := Height;
    end;
    { fix start }
    if FOleInplaceObject <> nil then 
    begin
      LRect := Rect(Left, Top, AWidth, AHeight);
      FOleInplaceObject.SetObjectRects(LRect, LRect);
    end;
    { fix end }
  end;
  inherited SetBounds(ALeft, ATop, AWidth, AHeight);
end;

将其应用于 OleCtrl 的本地副本后一切正常。

如何对齐 Windows Media Player 控件以适合父级 window？

How to align Windows Media Player control to fit parent window?

delphi

wmp

delphi-7

windows-media-player