记录、证明不相关和 John Major 的平等

Question

假设我有以下类型的记录：

Record R (A : Type) (P : A -> Prop) := {val : A; prop : P val}.

要证明两个这样的记录相等，（通过证明不相关）证明它们的字段 val 相等就足够了：

Goal forall A P (r1 r2 : R A P), val _ _ r1 = val _ _ r2 -> r1 = r2.
destruct r1, r2.
simpl.
intro H.
revert prop0.
rewrite H.
intros.
f_equal.
apply proof_irrelevance.
Qed.

在 John Major 平等的情况下，是否可以证明类似的目标（可能依赖安全公理）？这是我失败的尝试：

Goal forall A1 A2 P1 P2 (r1 : R A1 P1) (r2 : R A2 P2),
JMeq (val _ _ r1) (val _ _ r2) -> JMeq r1 r2.
destruct r1, r2.
simpl.
intro H.
revert prop0.
Fail rewrite H.

Answer 1

不，它不是（当然不假设 False）。问题是 JMeq 意味着类型相等：

Require Import Coq.Logic.JMeq.

Record R (A : Type) (P : A -> Prop) := {val : A; prop : P val}.

Axiom contra : forall A1 A2 P1 P2 (r1 : R A1 P1) (r2 : R A2 P2),
JMeq (val _ _ r1) (val _ _ r2) -> JMeq r1 r2.

Goal False.
assert (H1 := contra nat nat (fun n => True) (eq 0) (Build_R _ _ 0 I) (Build_R _ _ 0 eq_refl)).
assert (H2 : R nat (fun n => True) = R nat (eq 0) :> Type).
{ now destruct H1. }
assert (H3 : forall r1 r2 : R nat (fun _ => True), r1 = r2).
{ rewrite H2. intros [n1 p1] [n2 p2].
  now destruct p1; destruct p2. }
specialize (H3 (Build_R _ _ 0 I) (Build_R _ _ 1 I)).
discriminate.
Qed.

记录、证明不相关和 John Major 的平等

Record, Proof irrelevance, and John Major's equality

coq

dependent-type