多条件数组公式有忽略空白单元格的问题

Question

我正在尝试使用数组公式来计算 Excel 集中包含空白单元格的数据的加权平均值，但我很困惑为什么会出现错误。我想根据与另一个数组的相对位置排除两部分数据。

这是我的数据

A    B        C
0.03
0.06
0.09
0.12
0.18 1.87E-06 0.236033
0.21 4.04E-05 0.249285
0.24 8.31E-05 0.268155
0.27 1.54E-04 0.268104
0.30 2.49E-04 0.274135
0.33 3.08E-04 0.301185
0.36 4.06E-04 0.311255
0.39 4.70E-04 0.329554
0.42 5.39E-04 0.332625
0.45 5.97E-04 0.339827
0.48 6.69E-04 0.347729
0.51 7.54E-04 0.359481
0.54 8.49E-04 0.371833
0.57 9.46E-04 0.379580
0.60 1.08E-03 0.386926

这是我的数组公式。 {=SUMPRODUCT(IF(AND($A3:$A22<0.5,$A3:$A22>0.2),$B3:$B22,""),IF(AND($A3:$A22<0.5,$A3:$A22>0.2),$C3:$C22,""))/SUM(IF(AND($A3:$A22<0.5,$A3:$A22>0.2),$B3:$B22,""))}

我不明白为什么这个数组公式不起作用。如果我将 if 语句中的 and 替换为一个条件，那么这可以正常工作，返回值 0.321592。 {=SUMPRODUCT(IF($A3:$A22<0.5,$B3:$B22,""),IF($A3:$A22<0.5,$C3:$C22,""))/SUM(IF($A3:$A22<0.5,$B3:$B22,""))}

我想这可能是因为我有一些空白单元格，但它们不在我应用逻辑语句的列中，所以我很困惑。我想得到一个解决方案，以便我可以将此 if 语句与 and 或数组公式中的一些变通方法一起应用。谢谢

Answer 1

因为AND不能return数组，所以return只能TRUE或FALSE。试试下面的数组公式：

{=SUMPRODUCT(($A3:$A22<0.5)*($A3:$A22>0.2)*($B3:$B22),($A3:$A22<0.5)*($A3:$A22>0.2)*($C3:$C22))/SUM(($A3:$A22<0.5)*($A3:$A22>0.2)*($B3:$B22))}

结果是否符合要求？

Answer 2

我更喜欢接受的答案，因为数组公式更短，但这也给出了准确的结果。

{==SUMPRODUCT(IF($A3:$A22<0.5,IF($A3:$A22>0.2,$B3:$B22,""),""),IF($A3:$A22<0.5,IF($A3:$A22>0.2,$C3:$C22,""),""))/SUM(IF($A3:$A22<0.5,IF($A3:$A22>0.2,$B3:$B22,""),""))}

多条件数组公式有忽略空白单元格的问题

Multi-condition array formula having issue ignoring blank cells

arrays

excel

if-statement

array-formulas

blank-line