CMakeLists：使用 ExternalProject 添加来自 Github 的源文件

Question

我正在为 Beckhoff ADS 库编写一个小的 catkin 包装器。我想安装 AdsLib 文件夹中的文件，但不使用 Beckhoff 的 CMake 文件。

我只想复制文件，以便将它们添加到我自己的 CMakeLists 中的库中。如果我手动复制文件，这很好用。但我想直接使用 Github 源中的最新文件进行构建。

我尝试了在 Whosebug 上可以找到的所有可能的组合，但不知何故无法实现。

cmake_minimum_required(VERSION 2.8.3)
project(ads_catkin)

find_package(catkin_simple REQUIRED)
catkin_simple()

include(ExternalProject)


ExternalProject_Add(ads
    PREFIX ${CMAKE_BINARY_DIR}/ads
    GIT_REPOSITORY https://github.com/Beckhoff/ADS.git
    GIT_TAG master
    CONFIGURE_COMMAND ""
    #GIT_TAG 6b3a03009a757cf651fe44d8be7b6df698028f0e
    UPDATE_COMMAND ""
    BUILD_COMMAND ""
    INSTALL_COMMAND ""
)

ExternalProject_Get_Property(ads source_dir)

cs_add_library(${PROJECT_NAME}
    ${source_dir}/AdsLib/AdsDef.cpp
)
cs_install()
cs_export()

我第一次使用 catkin_tools 构建时，这给了我：

Errors     << ads_catkin:cmake /home/xxx/xxx_ws/logs/ads_catkin/build.cmake.000.log                                 
CMake Error at /home/xxx/xxx_ws/devel/share/catkin_simple/cmake/catkin_simple-extras.cmake:150 (add_library):
  Cannot find source file:

    /home/xxx/xxx/build/ads_catkin/ads/src/ads/AdsLib/AdsDef.cpp

  Tried extensions .c .C .c++ .cc .cpp .cxx .m .M .mm .h .hh .h++ .hm .hpp
  .hxx .in .txx
Call Stack (most recent call first):
  CMakeLists.txt:23 (cs_add_library)


CMake Error: CMake can not determine linker language for target: ads_catkin
CMake Error: Cannot determine link language for target "ads_catkin".

然后，我第二次运行使用相同代码构建工具时，文件实际上被克隆了，但我最终遇到了这个错误：

Errors     << ads_catkin:make /home/xxx/xxx_ws/logs/ads_catkin/build.make.000.log                                   
make[2]: *** No rule to make target 'CMakeFiles/ads_catkin.dir/build'.  Stop.
make[1]: *** [CMakeFiles/ads_catkin.dir/all] Error 2
make[1]: *** Waiting for unfinished jobs....
Cloning into 'ads'...
Already on 'master'
make: *** [all] Error 2

顺便说一句：cs_add_library 是 add_library 和 target_link_libraries 的 catkin_simple 形式。

更新：越来越近了……将@Tsyvarev 的解决方案应用到我的文件中：

cmake_minimum_required(VERSION 2.8.3)
project(ads_catkin)

find_package(catkin_simple REQUIRED)
catkin_simple()

include(ExternalProject)


ExternalProject_Add(ads
    PREFIX ${CATKIN_DEVEL_PREFIX}/ads
    GIT_REPOSITORY https://github.com/Beckhoff/ADS.git
    GIT_TAG 6b3a03009a757cf651fe44d8be7b6df698028f0e
    #GIT_TAG master
    CONFIGURE_COMMAND ""
    UPDATE_COMMAND ""
    BUILD_COMMAND ""
    INSTALL_COMMAND ""
    BUILD_BYPRODUCTS 
        <SOURCE_DIR>/AdsLib/AdsDef.cpp
        <SOURCE_DIR>/AdsLib/AdsLib.cpp
        <SOURCE_DIR>/AdsLib/AmsConnection.cpp
        <SOURCE_DIR>/AdsLib/AmsPort.cpp
        <SOURCE_DIR>/AdsLib/AmsRouter.cpp
        <SOURCE_DIR>/AdsLib/Frame.cpp
        <SOURCE_DIR>/AdsLib/Log.cpp
        <SOURCE_DIR>/AdsLib/NotificationDispatcher.cpp
        <SOURCE_DIR>/AdsLib/Sockets.cpp
        <SOURCE_DIR>/AdsLib/AdsDef.h
        <SOURCE_DIR>/AdsLib/AdsLib.h
        <SOURCE_DIR>/AdsLib/AdsNotification.h
        <SOURCE_DIR>/AdsLib/AmsConnection.h
        <SOURCE_DIR>/AdsLib/AmsHeader.h
        <SOURCE_DIR>/AdsLib/AmsPort.h
        <SOURCE_DIR>/AdsLib/AmsRouter.h
        <SOURCE_DIR>/AdsLib/Frame.h
        <SOURCE_DIR>/AdsLib/Log.h
        <SOURCE_DIR>/AdsLib/NotificationDispatcher.h
        <SOURCE_DIR>/AdsLib/RingBuffer.h
        <SOURCE_DIR>/AdsLib/Router.h
        <SOURCE_DIR>/AdsLib/Semaphore.h
        <SOURCE_DIR>/AdsLib/Sockets.h
        <SOURCE_DIR>/AdsLib/wrap_endian.h
        <SOURCE_DIR>/AdsLib/wrap_socket.h
)

ExternalProject_Get_Property(ads SOURCE_DIR)


include_directories(
    ${SOURCE_DIR}/AdsLib
)

cs_add_library(AdsLib
    ${SOURCE_DIR}/AdsLib/AdsDef.cpp
    ${SOURCE_DIR}/AdsLib/AdsLib.cpp
    ${SOURCE_DIR}/AdsLib/AmsConnection.cpp
    ${SOURCE_DIR}/AdsLib/AmsPort.cpp
    ${SOURCE_DIR}/AdsLib/AmsRouter.cpp
    ${SOURCE_DIR}/AdsLib/Frame.cpp
    ${SOURCE_DIR}/AdsLib/Log.cpp
    ${SOURCE_DIR}/AdsLib/NotificationDispatcher.cpp
    ${SOURCE_DIR}/AdsLib/Sockets.cpp
)
add_dependencies(AdsLib ads)


cs_install()

install(DIRECTORY ${SOURCE_DIR}/AdsLib/
        DESTINATION ${CATKIN_PACKAGE_INCLUDE_DESTINATION}
        PATTERN ".cpp" EXCLUDE   
)

cs_export()

我试图将头文件包含在我的 AdsLib 库中。但是我仍然得到一个错误：

In file included from /home/xxx/xxx_ws/src/xxx/nav_controller/src/controller.cpp:19:0:
/home/xxx/xxx_ws/src/xxx/nav_controller/include/nav_controller/controller.h:27:10: fatal error: AdsLib.h: No such file or directory
 #include "AdsLib.h"
          ^~~~~~~~~~~~~~~~~
compilation terminated.
make[2]: *** [CMakeFiles/nav_controller.dir/src/controller.cpp.o] Error 1
make[2]: *** Waiting for unfinished jobs....
In file included from /home/xxx/xxx_ws/src/xxx/nav_controller/src/test.cpp:22:0:
/home/xxx/xxx_ws/src/xxx/nav_controller/include/nav_controller/controller.h:27:10: fatal error: AdsLib.h: No such file or directory
 #include "AdsLib.h"
          ^~~~~~~~~~~~~~~~~
compilation terminated.
make[2]: *** [CMakeFiles/nav_controller.dir/src/test.cpp.o] Error 1
make[1]: *** [CMakeFiles/nav_controller.dir/all] Error 2
make: *** [all] Error 2

Answer 1

CMake 错误 Cannot find source file 意味着一个简单的事情：没有告诉 CMake 给定的源文件是 生成的 并且文件本身不存在。

因为文件是在ExternalProject_Add生成的，需要调整对应的target-level依赖：

add_dependency(ads_catkin ads)

此命令应在 add_library() 和 ExternalProject_Add 调用创建相应目标后发出。此命令告诉 CMake 只有在执行了外部项目的所有步骤后才应构建库。

你还需要告诉CMake源文件已经生成了。有两种方法可以做到这一点。

设置已生成属性:

set_source_files_properties(${source_dir}/AdsLib/AdsDef.cpp PROPERTIES GENERATED TRUE)

这会阻止 CMake 在配置阶段搜索文件。

在生成它的目标的 BYPRODUCTS 选项中列出文件。对于由 ExternalProject_Add 命令创建的目标，这是通过该命令的附加选项实现的
```
BUILD_BYPRODUCTS <SOURCE_DIR>/AdsLib/AdsDef.cpp
```
与第一种情况一样，这也为源文件设置了 GENERATED 属性。但是 BYPRODUCTS 也使您的项目可供 Ninja 用户使用。

（在上面的选项中，<SOURCE_DIR>是一种引用ExternalProject源目录的特殊方式。它可用于某些ExternalProject的选项，BUILD_BYPRODUCTS就是其中之一）。

从技术上讲，CMake 应该足够聪明，可以在看到相应的 BYPRODUCTS 选项时自动添加目标级依赖项（add_dependency(ads_catkin ads) 的效果）。但是这个功能只针对3.16版本描述，不知道旧版本是否有效。

Answer 2

最后，即使在@Tsyvarev 的大力帮助下，我也无法使用 ExternalProject_Add 使其工作。部分解决方案是使用 cs_export(INCLUDE_DIRS ${ads}) 手动导出库，但不适用于 ExternalProject_Add，因为此时文件不可用。

最后，我在我的包中包含了 DownloadProject module，它是 FetchContent 的前身。这是它应该做的。

CMakeLists：使用 ExternalProject 添加来自 Github 的源文件

CMakeLists: Adding source files from Github with ExternalProject

c++

cmake

catkin