访问导出子表单到 excel

Question

我正在尝试编写一些 VBA 来从子表单中导出过滤后的记录。我发现了一些与此问题相关的 post 并且我从那些 post.

中拼凑了下面的代码

当我运行时，我收到运行次错误提示：

the Object '__temp' already exist.

当我点击调试时，它突出显示了行

Set qrydef = db.CreateQueryDef(strTempQryDef, strSQL)

谢谢你的帮助。

Private Sub ExportSubform()

    Dim db As dao.Database
    Dim qrydef As dao.QueryDef

    Dim strSQL As String
    Dim bolWithFilterOn As Boolean
    Dim strTempQryDef As String
    Dim strRecordSource As String

    strTempQryDef = "__temp"

    bolWithFilterOn = me.subsearch_frm.Form.FilterOn

    strRecordSource = me.subsearch_frm.Form.RecordSource

    If InStr(strRecordSource, "SELECT ") <> 0 Then
        strSQL = strRecordSource
    Else
        strSQL = "SELECT * FROM [" & strRecordSource & "]"
    End If

    ' just in case our sql string ends with ";"
    strSQL = Replace(strSQL, ";", "")

    If bolWithFilterOn Then
        strSQL = strSQL & _
        IIf(InStr(strSQL, "WHERE ") <> 0, " And ", " Where ") & _
        me.subsearch_frm.Form.Filter
    End If

    Set db = CurrentDb

    'create temporary query
    Set qrydef = db.CreateQueryDef(strTempQryDef, strSQL)
    db.QueryDefs.Append qrydef
    Set qrydef = Nothing

    DoCmd.TransferSpreadsheet TransferType:=acExport, _
    SpreadsheetType:=acSpreadsheetTypeExcel12Xml, _
    TableName:=strTempQryDef, _
    FileName:=Replace(CurrentProject.Path & "\", "\", "\") & strTempQryDef & ".xlsx"

    ' Delete the temporary query
    db.QueryDefs.Delete strTempQryDef

    Set db = Nothing

End Sub

Answer 1

根据 documentation:

If the object specified by name is already a member of the QueryDefs collection, a run-time error occurs.

因此，您应该在尝试创建临时查询之前将其删除。为此，您可以使用以下代码：

On Error Resume Next
DoCmd.DeleteObject acQuery, strTempQryDef
On Error GoTo 0

此外，根据 documentation：

In a Microsoft Access workspace, if you provide anything other than a zero-length string for the name when you create a QueryDef, the resulting QueryDef object is automatically appended to the QueryDefs collection.

因此，您不需要此行：

db.QueryDefs.Append qrydef

访问导出子表单到 excel

Access Export Subform to excel

forms

ms-access

vba

export-to-excel