将游标转换为 T-SQL

Question

我有下面的光标，效果很好。主要问题是运行需要一个多小时，这是个问题。

谁能看到如何将其转换为 T-SQL 语句？

DECLARE @VisitID int
DECLARE @PreviousVisitID int
DECLARE @VisitTimeIn datetime
DECLARE @Area1TimeIn datetime
DECLARE @Area1TimeOut datetime
DECLARE @Area2TimeIn datetime
DECLARE @Area2TimeOut datetime
DECLARE @Area3TimeIn datetime
DECLARE @Area3TimeOut datetime

DECLARE db_cursor CURSOR FOR 
select distinct VisitID from #temp

OPEN db_cursor  
FETCH NEXT FROM db_cursor INTO @VisitID  

WHILE @@FETCH_STATUS = 0  
BEGIN  

    select @VisitTimeIn = TimeIn from Visit where VisitID = @VisitID

    select @Area1TimeIn = @VisitTimeIn
    select @Area1TimeOut = DateAdd(ss,500,@Area1TimeIn)
    select @Area2TimeIn = @Area1TimeOut
    select @Area2TimeOut = DateAdd(ss,500,@Area2TimeIn)
    select @Area3TimeIn = @Area2TimeOut
    select @Area3TimeOut = DateAdd(ss,500,@Area3TimeIn)

    Update VisitTransitions Set TimeIn = @Area1TimeIn where VisitID = @VisitID and AreaName = '1'
    Update VisitTransitions Set TimeOut = @Area1TimeOut where VisitID = @VisitID and AreaName = '1'
    Update VisitTransitions Set TimeIn = @Area2TimeIn where VisitID = @VisitID and AreaName = '2'
    Update VisitTransitions Set TimeOut = @Area2TimeOut where VisitID = @VisitID and AreaName = '2'
    Update VisitTransitions Set TimeIn = @Area3TimeIn where VisitID = @VisitID and AreaName = '3'
    Update VisitTransitions Set TimeOut = @Area3TimeOut where VisitID = @VisitID and AreaName = '3'

    Update Visit Set TimeOut = @Area3TimeOut where VisitID = @VisitID

    FETCH NEXT FROM db_cursor INTO @VisitID 
END 

CLOSE db_cursor  
DEALLOCATE db_cursor

Answer 1

这显然是未经测试的。您需要向我们提供一些示例数据以使其完美。但下面是一个开始。除了为每个值增加 500 秒之外，您似乎没有对时间值和超时值做任何特殊的事情，所以：

BEGIN TRAN;

UPDATE vt
SET vt.TimeIn = v.TimeIn,
vt.TimeOut = DateAdd(ss,500,v.TimeIn)
FROM dbo.VisitTransitions vt
INNER JOIN #tmp t ON t.VisitId = vt.VisitId
INNER JOIN dbo.Visit v ON v.VisitID = vt.VisitID
AND AreaName = '1';

UPDATE vt
SET vt.TimeIn = DateAdd(ss,500,v.TimeIn),
vt.TimeOut = DateAdd(ss,1000,v.TimeIn)
FROM dbo.VisitTransitions vt
INNER JOIN #tmp t ON t.VisitId = vt.VisitId
INNER JOIN dbo.Visit v ON v.VisitID = vt.VisitID
AND AreaName = '2';

UPDATE vt
SET vt.TimeIn = DateAdd(ss,1000,v.TimeIn),
vt.TimeOut = DateAdd(ss,1500,v.TimeIn)
FROM dbo.VisitTransitions vt
INNER JOIN #tmp t ON t.VisitId = vt.VisitId
INNER JOIN dbo.Visit v ON v.VisitID = vt.VisitID
AND AreaName = '3';

UPDATE v
SET v.TimeOut = DateAdd(ss,1500,v.TimeIn)
FROM Visit v
INNER JOIN #tmp t ON t.VisitId = v.VisitId;

--COMMIT TRAN;
--ROLLBACK TRAN;

Answer 2

当您谈到性能时，我首先想到的是确保您在 VisitTransitions.VisitId（当然还有 Visit.VisitId）上有一个索引。但是在没有迭代的重写方面，我想知道你是否考虑过类似以下两个语句的内容：

UPDATE vt
SET 
 vt.TimeIn = CASE WHEN vt.AreaName = '1' THEN v.TimeIn WHEN vt.AreaName = '2' THEN DateAdd(ss, 500, v.TimeIn) ELSE DateAdd(ss, 1000, v.TimeIn) END,
 vt.TimeOut = CASE WHEN vt.AreaName = '1' THEN DateAdd(ss, 500, v.TimeIn) WHEN vt.AreaName = '2' THEN DateAdd(ss, 1000, v.TimeIn) ELSE DateAdd(ss, 1500, v.TimeIn) END
FROM VisitTransitions vt 
 INNER JOIN Visit v
  ON v.VisitID = vt.VisitID
 INNER JOIN #temp t
  ON v.VisitID = t.VisitID;

UPDATE v
SET 
  v.TimeOut = DateAdd(ss, 1500, v.TimeIn)
FROM Visit v
  ON v.VisitID = vt.VisitID
INNER JOIN #temp t
  ON v.VisitID = t.VisitID;

如果除了 (1,2,3) 之外还有 AreaNames，这可能不完全正确，但原则上我认为它会起作用，您可以以此为基础。

将游标转换为 T-SQL

Convert Cursor to T-SQL

sql

sql-server

tsql

database-cursor