LLVM 不一致的编号方案

Question

我一直在研究编译器，并且一直在开发我自己的玩具 C 编译器。目前我正在尝试以 LLVM IR 为目标，但我无法理解语法。

我当前的问题：为什么这个有效的 IR 语法：

define i32 @main() {
    %1 = alloca i32, align 4
    %2 = add i32 0, 0
    store i32 %2, i32* %1, align 4
    %3 = alloca i32, align 4
    %4 = add i32 0, 1
    store i32 %4, i32* %3, align 4
    %5 = load i32, i32* %1, align 4
    %6 = icmp ne i32 %5, 0
    br i1 %6, label %true0, label %else0
true0:                          ; preds %0
    %7 = add i32 0, 1
    store i32 %7, i32* %3, align 4
    br label %end0
else0:                          ; preds %0
    %8 = load i32, i32* %3, align 4
    %9 = icmp ne i32 %8, 0
    br i1 %9, label %true1, label %end1
true1:                      ; preds %else0
    %10 = add i32 0, 2
    store i32 %10, i32* %3, align 4
    br label %end1
end1:                       ; preds %true1, %else0
    br label %end0
end0:                           ; preds %true0, %else1
    %11 = load i32, i32* %3, align 4
    ret i32 %11
}

但这不是：

define i32 @main() {
    %1 = alloca i32, align 4
    %2 = add i32 0, 0
    store i32 %2, i32* %1, align 4 ; variable a
    %3 = load i32, i32* %1, align 4
    %4 = icmp ne i32 %3, 0
    br i1 %4, label %true0, label %else0
true0: ; preds %0
    %5 = add i32 0, 1
    ret i32 %5
    br label %end0
else0: ; preds %0
    %6 = add i32 0, 2
    ret i32 %6
    br label %end0
end0: ; % preds %true0, %else0
    ret i32 0
}

我收到错误：

llc-6.0: test2.ll:13:1: error: instruction expected to be numbered '%7'
%6 = add i32 0, 2
^

我不明白为什么该块需要是 %7，因为之前使用的数字是 %6。比较第一个示例的 %else0 标签，这是非常相似的语法并且工作正常。

是的，我的编译器需要大量优化，但我还没有完成 :)

Answer 1

您的代码无效，因为实际上还有一个您没有标记的基本块：

true0: ; preds %0
    %5 = add i32 0, 1
    ret i32 %5
hidden_bb: ; this will named as %6 by default
    br label %end0
else0: ; preds %0

如果它有标签，错误就会消失。请注意，所有终止符指令，如 br 和 ret 将创建自己的基本块。

LLVM 不一致的编号方案

LLVM inconsistent numbering scheme

llvm

llvm-ir