如何使用 ObjectDBX 使用 AutoLISP 从所有块中删除所有属性

Question

我想使用 AutoLISP ObjectDBX 方法删除图形中块的所有属性。

下面的程序运行良好：它删除了图形中所有块的属性，但是当我在块编辑器中编辑该块时，我看到所有属性都还在。

我想我需要从块的定义中删除这个属性。

;[dwgin]--input drawing file
;[dwgout]-- Output drawing fath with name
;function 'LM:GetDocumentObject' lee mac function to open drawing in ObjectDBX method
(defun DBXAttDelete ( dwgin dwgout / doc flg val )
    (if (setq doc (LM:GetDocumentObject dwgin))
        (progn
            (vlax-for lyt (vla-get-layouts doc)
                (vlax-for obj (vla-get-block lyt)
                    (if (and (= "AcDbBlockReference" (vla-get-objectname obj))
                             (= :vlax-true (vla-get-hasattributes obj))
                        )
                        (foreach att (vlax-invoke obj 'getattributes)              

                    (if (vl-catch-all-error-p (setq err (vl-catch-all-apply 'vla-delete (list att))))
                      (princ (strcat "\nERROR: " (vl-catch-all-error-message err)))

                    )
                        )
                    )
                )
            )
           (vla-saveas doc dwgout)
            (vlax-release-object doc)
            flg
        )
        (prompt (strcat "\nThe drawing \"" dwgin "\" was not found or could not be accessed."))
    )
)

你能帮我找到我需要improve/correct这个程序的地方吗？

Answer 1

考虑到块定义本质上是块的 "blueprint"，每个块引用都是一个实例，显示在块定义中找到的对象，在特定位置、比例、旋转和方向绘图.

属性也有 Attribute Definitions within the Block Definition, and corresponding Attribute References 附加到每个块参考。这样的属性引用然后可以为绘图中插入的每个块引用保存不同的文本内容。

除此之外，有趣的是，属性引用也可以独立于块定义以编程方式附加到块引用，但是，当使用标准的现成前端操作 AutoCAD 时，这是不允许的。

因此，要从图形中删除所有属性，您需要删除与所有块参照关联的属性参照，以及相应块定义中的属性定义。

您可能还想在执行删除操作之前解锁锁定的图层，并在执行此操作后重新锁定之前锁定的图层。

由于布局只是块的一种类型，迭代块集合将足以处理所有布局、块和嵌套块（不包括外部参照）：

(defun DBXAttDelete ( dwgin dwgout / doc lck )
    (if (setq doc (LM:GetDocumentObject dwgin))
        (progn
            (vlax-for lay (vla-get-layers doc)
                (if (= :vlax-true (vla-get-lock lay))
                    (progn
                        (setq lck (cons lay lck))
                        (vla-put-lock lay :vlax-false)
                    )
                )
            )
            (vlax-for blk (vla-get-blocks doc)
                (if (= :vlax-false (vla-get-isxref blk))
                    (vlax-for obj blk
                        (cond
                            (   (= "AcDbBlockReference" (vla-get-objectname obj))
                                (if (= :vlax-true (vla-get-hasattributes obj))
                                    (foreach att (vlax-invoke obj 'getattributes)
                                        (vla-delete att)
                                    )
                                )
                            )
                            (   (= "AcDbAttributeDefinition" (vla-get-objectname obj))
                                (vla-delete obj)
                            )
                        )
                    )
                )
            )
            (foreach lay lck
                (vla-put-lock lay :vlax-true)
            )
            (vla-saveas doc dwgout)
            (vlax-release-object doc)
            t
        )
        (prompt (strcat "\nThe drawing \"" dwgin "\" was not found or could not be accessed."))
    )
)

如何使用 ObjectDBX 使用 AutoLISP 从所有块中删除所有属性

How to delete all Attributes from all Blocks with AutoLISP using ObjectDBX

lisp

autocad

autolisp

autocad-plugin

autocad-scripts