QTimer::singleShot 相当于 QML

Question

考虑这个 C++ 语句（示例 from docs）：

QTimer::singleShot(600000, &app, SLOT(quit()));

如何在 .qml 中做同样的事情 JavaScript，像这样的 QML：

Rectangle {
    property int counter: 0
    onCounterChanged: {
        if (counter > 42) {
            // do equivalent of above C++ statement here
        }
    }
    // more code, which actually manipulates counter 
}

有一个明显的解决方案，即使用单独的 Timer，然后由 JavaScript 代码启动，如果不可能使用单行代码，我将接受它作为答案。是吗？

Answer 1

将 Timer 对象的 "repeat" 属性更改为 false。

import QtQuick 1.0

Item {
    Timer {
        id: timer
        interval: 600000
        running: false
        repeat: false
        onTriggered: Qt.quit()
    }

    Rectangle {
        property int counter: 0
        onCounterChanged: {
            if (counter > 42) {
                timer.running = true
            }
        }
    }
}

Answer 2

我最终将此添加到我的 main.qml:

Component {
    id: delayCallerComponent
    Timer {
    }
}

function delayCall( interval, callback ) {
    var delayCaller = delayCallerComponent.createObject( null, { "interval": interval } );
    delayCaller.triggered.connect( function () {
        callback();
        delayCaller.destroy();
    } );
    delayCaller.start();
}

可以这样使用：

delayCall( 1000, function () { ... } );

Answer 3

以下是使用 SequentialAnimation 元素的方法：

SequentialAnimation {
    id: quitTimer
    PauseAnimation { duration: 60000 }
    ScriptAction { script: Qt.quit() }
}

Rectangle {
    property int counter: 0
    onCounterChanged: {
        if (counter > 42) {
            quitTimer.start()
        }
    }
}

如果这太丑了，用它做一个组件：

// SingleshotTimer.qml
import QtQuick 2.0
SequentialAnimation {
    property alias delay: delayAnim.duration
    property alias script: scriptAction.script

    PauseAnimation { id: delayAnim; duration: 10000 }
    ScriptAction { id: scriptAction }
}

使用这个新组件可以满足您的需求：

SingleshotTimer { id: timer; delay: 60000; script: Qt.quit() }

Rectangle {
    property int counter: 0
    onCounterChanged: {
        if (counter > 42) {
            timer.start()
        }
    }
}

Answer 4

QML中有定时器组件

import QtQuick 2.0

Item {
    Timer {
        interval: 500; running: true; repeat: true
        onTriggered: time.text = Date().toString()
    }

    Text { id: time }
}

了解更多详情see the documentation

QTimer::singleShot 相当于 QML

QTimer::singleShot equivalent for QML

qt

qml