为什么我们在为 Inno Setup 卸载程序换肤时需要使用 uninsneveruninstall 标志？

Question

我对此有点困惑VCL Styles plugin。我对 Uninstaller 方面特别感兴趣。

他们提供的样本是这样的：

#define VCLStylesSkinPath "{localappdata}\VCLStylesSkin"
[Files]
Source: ..\VclStylesinno.dll; DestDir: {#VCLStylesSkinPath}; Flags: uninsneveruninstall
Source: ..\Styles\Amakrits.vsf; DestDir: {#VCLStylesSkinPath}; Flags: uninsneveruninstall


[Code]
{ Import the LoadVCLStyle function from VclStylesInno.DLL }
procedure LoadVCLStyle(VClStyleFile: String);
  external 'LoadVCLStyleW@files:VclStylesInno.dll stdcall setuponly';
procedure LoadVCLStyle_UnInstall(VClStyleFile: String);
  external 'LoadVCLStyleW@{#VCLStylesSkinPath}\VclStylesInno.dll stdcall uninstallonly';
{ Import the UnLoadVCLStyles function from VclStylesInno.DLL }
procedure UnLoadVCLStyles;
  external 'UnLoadVCLStyles@files:VclStylesInno.dll stdcall setuponly';
procedure UnLoadVCLStyles_UnInstall;
  external 'UnLoadVCLStyles@{#VCLStylesSkinPath}\VclStylesInno.dll stdcall uninstallonly';

function InitializeSetup(): Boolean;
begin
  ExtractTemporaryFile('Amakrits.vsf');
  LoadVCLStyle(ExpandConstant('{tmp}\Amakrits.vsf'));
  Result := True;
end;

procedure DeinitializeSetup();
begin
  UnLoadVCLStyles;
end;

function InitializeUninstall: Boolean;
begin
  Result := True;
  LoadVCLStyle_UnInstall(ExpandConstant('{#VCLStylesSkinPath}\Amakrits.vsf'));
end;

procedure DeinitializeUninstall();
begin
  UnLoadVCLStyles_UnInstall;
end;

我对这个有点感兴趣：

Source: ..\VclStylesinno.dll; DestDir: {#VCLStylesSkinPath}; Flags: uninsneveruninstall
Source: ..\Styles\Amakrits.vsf; DestDir: {#VCLStylesSkinPath}; Flags: uninsneveruninstall

我知道需要安装这些文件，因为卸载程序需要这些文件。但是为什么要使用 uninsneveruninstall 标志呢？这是可以接受的行为吗？

Answer 1

这是一个 DLL。它已加载到卸载程序中。所以卸载程序不能删除它。所以标志在那里，以避免卸载程序在无意义地尝试删除文件时失败。

为了更好的解决方案，请参阅我的回答的第二部分：

为什么我们在为 Inno Setup 卸载程序换肤时需要使用 uninsneveruninstall 标志？

Why do we need to use the uninsneveruninstall flag when skinning a Inno Setup Uninstaller?

inno-setup

skinning

uninstallation

vcl-styles