比较 [Sheet 2] 与 [Sheet 1] 并将 [Sheet 1] 中任何缺失的唯一数字添加到 [Sheet 2 中 table 的底部]

Question

只是想知道是否有人可以帮助解决以下问题：我有两个 sheet:

迷你大师
关键路径

每天都会向迷你大师添加新数据。两个 Mini Master 关键路径都在 A 列中拥有唯一编号。

我想要运行一个宏，将 Mini Master 中的 A 列与关键路径中的 A 列进行比较。

如果 Mini Master 有任何唯一编号（未列在关键路径的 A 列中），我想将它们复制并粘贴到关键路径的底部 Table。

数据应该只流向 Mini Master > Critical path。从不关键路径 > 迷你大师。

示例：如果我能找到一个宏来识别丢失的唯一编号，例如下图中的编号（以粉红色突出显示），那就太好了。

迷你大师Sheet

然后将该唯一编号复制并粘贴到关键路径 table 的底部 Sheet（也以粉红色突出显示）

关键路径Sheet

数据输入后，我编写了一个代码，使关键路径 Sheet 与 Mini Master 中所做的任何更改保持同步，然后将填充 B、C 和 D 列。

提前感谢您的帮助。

Answer 1

试试，

Sub test()
    Dim Ws As Worksheet
    Dim toWs As Worksheet
    Dim rngDB As Range, rngT As Range
    Dim vDB As Variant, vR() As Variant
    Dim i As Long, n As Long, j As Integer

    Set Ws = Sheets("MINI MASTER")
    Set toWs = Sheets("CRITICAL PATH")

    vDB = Ws.Range("a1").CurrentRegion
    With toWs
        Set rngDB = .Range("a2", .Range("a" & Rows.Count).End(xlUp))
        For i = 2 To UBound(vDB, 1)
            If WorksheetFunction.CountIf(rngDB, vDB(i, 1)) Then
            Else
                n = n + 1
                ReDim Preserve vR(1 To 4, 1 To n)
                For j = 1 To 4
                    vR(j, n) = vDB(i, j)
                Next j
            End If
        Next i
        Set rngT = .Range("a" & Rows.Count).End(xlUp)(2)
        If n Then
            rngT.Resize(n, 4) = WorksheetFunction.Transpose(vR)
        End If
    End With
End Sub

比较 [Sheet 2] 与 [Sheet 1] 并将 [Sheet 1] 中任何缺失的唯一数字添加到 [Sheet 2 中 table 的底部]

Compare [Sheet 2] to [Sheet 1] & add any missing unique numbers in [Sheet 1] to the bottom of table in [Sheet 2]

excel

vba

loops

copy-paste