使用 millis 打开蠕动泵继电器 x 时间

Question

这是我在 arduino 中的第一个代码。我正在尝试为我的花园构建一个简单的自动化浇水系统。该代码包含 3 个主要功能，即：

给肥箱加水。
向水箱中添加肥料，同时加水与假定肥料在这个过程中混合。
全天自动浇水。

对于第一个和第三个功能，我认为我已经完成了（理论上+小规模系统）。哈哈！

现在，对于 2 号肥料功能 (fertilizer_PUMP())，我使用 2 个蠕动泵将 AB 肥料溶液添加到罐中。我试图让泵在 x 时间内达到运行，但该功能仅运行一次，之后如果两个浮动开关变干并等待底部开关变湿，则需要重置回路再次。谁能帮助和指导我缺少哪一部分？我也愿意接受任何改进我的代码的建议。谢谢。

更新：

很抱歉让您感到困惑。实际上对于这个功能，以下是我的要求。

如果上漂干下漂湿 > 开启两个蠕动泵 10 秒（或更长时间，稍后会改变）然后停止。
然后，如果上漂干，下漂干>重置。
等待下一个上漂干和下漂湿。

真的很抱歉再次造成您的困惑。有点搞砸了之前的逻辑。

#include <Wire.h>
#include "RTClib.h"
RTC_DS1307 RTC;

#define relayON HIGH
#define relayOFF LOW
#define floatWET HIGH
#define floatDRY LOW

const byte bottom_float = 13; //bottom position float switch
const byte top_float = 12; //top position float switch
const byte relay_topup_PUMP = 2; //Relay 1 for PUMP/Solenoid to topup water into the fertilizer tank
const byte relay_watering_PUMP = 3; //Relay 2 for scheduled watering PUMP
const byte relay_fertilizer_PUMPA = 4; //Relay 3 for Peristaltic PUMP "A" solution fertilizer
const byte relay_fertilizer_PUMPB = 5; //Relay 4 for Peristaltic PUMP "B" solution fertilizer

unsigned long previousMillis = 0;   // stores last time relay was active(on)
unsigned long fertilizer_pumpON_interval = 10000; //(10s for testing)Time to turn ON fertilizer peristaltic pump to get required EC reading
void topup_PUMP();
void watering_PUMP();
void fertilizer_PUMP();

void setup ()
{
  Serial.begin (9600);
  Wire.begin();
  //  RTC.begin();

  if (! RTC.begin())
  {
    Serial.println("Couldn't find RTC");
    while (1);
  }
  if (! RTC.isrunning())
  {
    Serial.println("RTC is NOT running!");
  }
  // following line sets the RTC to the date & time this sketch was compiled
  // rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
  // This line sets the RTC with an explicit date & time, for example to set
  // January 21, 2014 at 3am you would call:
  // rtc.adjust(DateTime(2014, 1, 21, 3, 0, 0));

  pinMode (bottom_float, INPUT_PULLUP);
  pinMode (top_float, INPUT_PULLUP);
  pinMode (relay_topup_PUMP, OUTPUT);
  pinMode (relay_watering_PUMP, OUTPUT);
  pinMode (relay_fertilizer_PUMPA, OUTPUT);
  pinMode (relay_fertilizer_PUMPB, OUTPUT);

  //digitalWrite (relay_topup_PUMP, relayOFF);
  //digitalWrite (relay_watering_PUMP, relayOFF);
  digitalWrite (relay_fertilizer_PUMPA, relayOFF);
  digitalWrite (relay_fertilizer_PUMPB, relayOFF);

  DateTime now = RTC.now();
}   // end of setup

void loop ()
{
  //  topup_PUMP();
  //  watering_PUMP();
  fertilizer_PUMP();
}

//void topup_PUMP()
//{
//  if (digitalRead (top_float) == floatDRY && digitalRead (bottom_float) == floatDRY)
//  {
//    Serial.println("TOPUP PUMP ON");
//    digitalWrite(relay_topup_PUMP, relayON);
//  }
//
//  if (digitalRead (top_float) == floatWET && digitalRead (bottom_float) == floatWET)
//  {
//    Serial.println("TOPUP PUMP OFF");
//    digitalWrite(relay_topup_PUMP, relayOFF);
//  }
//  delay (1000);
//}
//
//void watering_PUMP()
//{
////  DateTime now = RTC.now();
//      Serial.print(now.hour(), DEC);
//      Serial.print(':');
//      Serial.print(now.minute(), DEC);
//      Serial.print(':');
//      Serial.print(now.second(), DEC);
//      Serial.print(' ');
//      Serial.print(now.day(), DEC);
//      Serial.print('/');
//      Serial.print(now.month(), DEC);
//      Serial.print('/');
//      Serial.print(now.year(), DEC);
//      Serial.println();
//      delay(1000);
//
//  boolean watering_PUMPstate = false;
//  if (now.hour() == 15 && now.minute() >= 38 && now.minute() < 39) watering_PUMPstate = true;    //6:00 am - 5 mins
//  if (now.hour() == 15 && now.minute() >= 40 && now.minute() < 41) watering_PUMPstate = true;  //8:30 am - 5 mins
////  if (now.hour() == 11 && now.minute() >= 0 && now.minute() < 5) watering_PUMPstate = true;  //11:00 am - 5 mins
////  if (now.hour() == 13 && now.minute() >= 30 && now.minute() < 35) watering_PUMPstate = true;  //1:30 pm - 5 mins
////  if (now.hour() == 16 && now.minute() >= 0 && now.minute() < 10) watering_PUMPstate = true;  //4:00 pm - 10 mins
//
//  if (watering_PUMPstate == true)
//  {
//    digitalWrite(relay_watering_PUMP, relayON);
//    Serial.print("\t");
//    Serial.println(F("Watering Plant"));
//    Serial.print("\t");
//    Serial.println();
//  }
//  else
//  {
//    digitalWrite(relay_watering_PUMP, relayOFF);
//  }
//}

void fertilizer_PUMP()
{
  unsigned long currentTime = millis();
  boolean fertilizer_pumpON = false;
  if ((digitalRead (top_float) == floatDRY) && (digitalRead (bottom_float) == floatWET) && (currentTime - previousMillis <= fertilizer_pumpON_interval)) //Turn on for 10s
  {
    Serial.print("\t");
    Serial.println(currentTime);
    delay (1000);
    fertilizer_pumpON = true;
  }

  if (fertilizer_pumpON == true)
  {
    Serial.print("\t");
    Serial.println(F("Adding Fertilizer A and B"));
    delay (1000);
    digitalWrite(relay_fertilizer_PUMPA, relayON);
    digitalWrite(relay_fertilizer_PUMPB, relayON);

  }
  else
  {
    digitalWrite(relay_fertilizer_PUMPA, relayOFF);
    digitalWrite(relay_fertilizer_PUMPB, relayOFF);

  }
}

Answer 1

将您的 currentTime 和 fertilizer_pumpON 定义为全局

unsigned long currentTime = 0;
unsigned long previousMillis = 0;   // stores last time relay was active(on)
unsigned long fertilizer_pumpON_interval = 10000; //(10s for testing)Time to turn ON fertilizer peristaltic pump to get required EC reading

然后在你的

函数无效fertilizer_PUMP()

    if ((digitalRead (top_float) == floatDRY) 
        && (digitalRead (bottom_float) == floatWET) 
        && (currentTime - previousMillis <= fertilizer_pumpON_interval))

应该包括泵的状态——我猜你只想进入 if on pump off 状态

if ((digitalRead (top_float) == floatDRY)  // CAN BOTH STATES BE AT THE SAME TIME??
      && (digitalRead (bottom_float) == floatWET) 
      && (currentTime - previousMillis <= fertilizer_pumpON_interval))

我减少到

 if((millis() - previousMillis > fertilizer_pumpON_interval) 
      && fertilizer_pumpON == true) {//time is up and state is on stop pump
      fertilizer_pumpON = false; // switch off
   }
  else if (PUMP_ON_condition == true && fertilizer_pumpON == false){ //check if we have to switch on
   fertilizer_pumpON = true; // switch on
    previousMillis  = millis(); // set timer to switch on time
   setRelaytoON = true; // Use YOUR COMMAND/PIN whatever you need
  }
  else {
 // DO NOTHING OR something while waiting or running use more ELSE IF if needed
  }

总结一下

检查运行停止时的状态和时间
检查 INIT command/conditions AND 状态设置状态和计时器
如果需要检查紧急停止
如果上述none适用something/nothing

将长子句分解为单个部分并检查状态是否可以一次具有不同的值（逻辑错误）

if (A == true && A == false)  // YOU CAN NEVER ENTER THIS CLAUSE

EDIT 实现了您描述的逻辑（阅读代码中的注释！）添加行

bool fertilizer_pumpON = false;

before Setup() 到全局变量并将 void fertilizer_PUMP() 替换为以下代码。提示：切勿使用 delay() - 这会阻止处理并使时间驱动逻辑变得无用。

void fertilizer_PUMP() {
  // If top float dry and bottom float wet > turn on both peristaltic pump for 10s(or more will change later) and stop  CODE STARTS HERE
  if ((digitalRead (top_float) == floatDRY) && (digitalRead (bottom_float) == floatWET) &&  fertilizer_pumpON == false) {      //Turn on
    Serial.print("\t");
    Serial.println(millis());
    // delay (1000); // NEVER use delays or the whole logic wont work - delays BLOCK processing!
    fertilizer_pumpON = true;
    previousMillis = millis();
    Serial.print("\t");
    Serial.println(F("Adding Fertilizer A and B"));
    // delay (1000);
    digitalWrite(relay_fertilizer_PUMPA, relayON);
    digitalWrite(relay_fertilizer_PUMPB, relayON);
  }
  else if (fertilizer_pumpON == true && (millis() - previousMillis > fertilizer_pumpON_interval)) {    //Run for 10s then stop
    digitalWrite(relay_fertilizer_PUMPA, relayOFF);
    digitalWrite(relay_fertilizer_PUMPB, relayOFF);
    fertilizer_pumpON = false;
    Serial.println(F("Time elapsed"));
  }
  // If top float dry and bottom float wet > turn on both peristaltic pump for 10s(or more will change later) and stop  CODE STARTS HERE
  // Then, if top float dry and bottom float dry > reset.   CODE ENDS HERE
  else  if ((digitalRead (top_float) == floatDRY) && (digitalRead (bottom_float) == floatDRY && fertilizer_pumpON == true) ) {
    digitalWrite(relay_fertilizer_PUMPA, relayOFF);
    digitalWrite(relay_fertilizer_PUMPB, relayOFF);
    fertilizer_pumpON = false;
    Serial.println(F("Reset condition encountered"));
  }
  // Then, if top float dry and bottom float dry > reset.   CODE ENDS HERE
  else {  // Wait for next top float dry and bottom float wet. 
    Serial.println(F("Waiting ......"));  // use only for testing comment out afterwards
  } 
}

代码会编译，所以逻辑测试由您决定。

Answer 2

您可能想要更改从循环中调用函数的方式：

定义全局变量unsigned long previousMillis=-1;然后在 void loop():

void loop()
{
  if((digitalRead (top_float) == floatDRY) && (digitalRead (bottom_float) == floatWET))
  { //If your above condition is correct(means you are read to pour fertilizer)
   if(previousMillis==-1)
    previousMillis=millis();//Set time elapsed till now in global variable
   if(previousMillis!=-1)
   {
    fertilizer_PUMP();//call function with a fixed previousMillis till millis()-previousMillis becomes 10s
   }
  }
}

然后在 fertilizer_PUMP():

void fertilizer_PUMP()
{
 boolean fertilizer_pumpON = false;
 if (millis() - previousMillis <= fertilizer_pumpON_interval)) //Turn on for 10s
 {
  Serial.print("\t");
  Serial.println(currentTime);
  delay (1000);//This delay is not required because your effective interval would be 5 seconds then(10/2)
  //As you have a delay(1000) in the next if block too.
  fertilizer_pumpON = true;
 }
...

在同一个函数中：

else
   {
     digitalWrite(relay_fertilizer_PUMPA, relayOFF);
     digitalWrite(relay_fertilizer_PUMPB, relayOFF);
     previousMillis=-1;//Wait for top float dry and bottom float wet, then set previousMillis
   }

使用 millis 打开蠕动泵继电器 x 时间

Turn on peristaltic pump relay for x amount of time using millis

c++

arduino

relay