运行时间错误“3706”：找不到提供商 - Excel VBA "Provider=Microsoft.Jet.OLEDB.4.0"

Question

我看到这个错误不是新出现的，但我找不到解决方案。

我有一个 xls 文件，它使用一个 sheet 就像 db 和 ADODB 我得到我需要的记录集。

代码非常简单，适用于我测试的每台电脑 (5)，使用 WIN7、WIN10、32 或 64 位。

但我在 PC 上，它是客户 PC，让我得到这个错误：Run time error '3706': Provider cannot be found，我查了WIN版，office版，和其他PC一样，WIN10 64位，MS Office 32位

我必须执行更多控制才能解决此问题？！？！感谢您的任何建议法布里齐奥

我的 xls 文件有 2 个 sheet，第一个名为 "dati"，有两列（Anno，Pezzi），第二个名为 "test" 为空，这是代码：

Sub testConn()
Dim cn As New ADODB.Connection
Dim rs As New ADODB.Recordset
Dim strsql As String
Const adOpenStatic = 3
Const adLockOptimistic = 3
Const adCmdText = &H1


Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

Set rs = New ADODB.Recordset
    #If Win64 Then
        cn.Open "Provider=Microsoft.Jet.OLEDB.12.0; Data Source=" & ThisWorkbook.FullName & "; Extended Properties=""Excel 8.0;HDR=Yes;"";"
    #Else
         cn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & ThisWorkbook.FullName & "; Extended Properties=""Excel 8.0;HDR=Yes;"";"
    #End If

strsql = "SELECT anno, Sum(Pezzi)as Tpz from [dati$] group by anno"

rs.Open strsql, cn, adOpenStatic, adLockReadOnly, adCmdUnspecified
rs.MoveFirst
With Worksheets("test")
    .Cells.ClearContents
    .Range("A1") = "Anno"
    .Range("B1") = "T.Pz"
    .Range("A2").CopyFromRecordset rs
    .Activate
    .Select
End With
End Sub

这些引用已添加到文件中：

Microsoft ActiveX Data Objects 6.1 Library
Microsoft ActiveX Data Recordset 2.8 Library

Answer 1

这个可以，有一些小细节不适合你使用。 12版，驱动是ace不是jet，扩展属性也是Excel12.0

并且不需要添加库。

Sub testConn()
Dim cn As Object
Dim rs As Object
Dim strsql As String
Dim connString


Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

    If Application.Version < 12 Then
        connString = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & ThisWorkbook.FullName & "; Extended Properties=""Excel 8.0;HDR=Yes;"";"
    Else
        connString = "Provider=Microsoft.ACE.OLEDB.12.0; Data Source=" & ThisWorkbook.FullName & "; Extended Properties=""Excel 12.0;HDR=Yes;"";"
    End If

cn.Open connString

strsql = "SELECT anno, Sum(Pezzi) as Tpz from [dati$] group by anno"

Set rs = cn.Execute(strsql)

With Worksheets("test")
    .Cells.ClearContents
    .Range("A1") = "Anno"
    .Range("B1") = "T.Pz"
    .Range("A2").CopyFromRecordset rs
    .Activate
    .Select
End With
End Sub

运行时间错误“3706”：找不到提供商 - Excel VBA "Provider=Microsoft.Jet.OLEDB.4.0"

Run time error '3706': Provider cannot be found - Excel VBA "Provider=Microsoft.Jet.OLEDB.4.0"

excel

vba

adodb

oledbconnection

运行 时间错误“3706”：找不到提供商 - Excel VBA "Provider=Microsoft.Jet.OLEDB.4.0"

Run time error '3706': Provider cannot be found - Excel VBA "Provider=Microsoft.Jet.OLEDB.4.0"

excel

vba

adodb

oledbconnection

运行时间错误“3706”：找不到提供商 - Excel VBA "Provider=Microsoft.Jet.OLEDB.4.0"