守卫中的语法错误导致未定义的函数

Question

我不知道是什么问题，这是代码-

solve_bdd(BddTree, ListVars) ->
  findRes(BddTree, maps:from_list(ListVars++[{one, 1}, {zero, 0}])).
findRes(BddTree, Map) when is_record(BddTree, node)-> Val = maps:get(getName(BddTree)), Name = getName(BddTree),
  if Name=='one' or Name=='zero' -> maps:get(getName(BddTree));
     (Val==1 or Val=='true') -> findRes(getRight(BddTree), Map);
     (Val==0 or Val=='false') -> findRes(getLeft(BddTree), Map);
     true -> error
  end;
findRes(_, _) -> error.

和 shell 错误-

exf.erl:183: syntax error before: '=='
exf.erl:180: function findRes/2 undefined
exf.erl:21: Warning: function getRight/1 is unused
exf.erl:22: Warning: function getLeft/1 is unused
error

Answer 1

当有多个条件时，您应该将 or 运算符的操作数分组在括号中：

1> false or false.
false

2> false == true or false == true.
* 1: syntax error before: '=='

2> (false == true) or (false == true).
false

您还使用了 maps:get/1（模块 maps 中的函数 get，它接受 1 个参数）：

maps:get( getName(BddTree) )

不存在！但您可以使用 maps:get/2 或 maps:get/3。

大多数时候您可以使用 case 表达式而不是 if 表达式。
另外有时最好使用 orlese 运算符而不是 or.
最好什么都不处理！您可以使用其中之一并删除不必要的检查，而不是同时处理 0 和 1 以及布尔类型。
按照 Erlang 的惯例，最好在 Snake_case 中编写函数和记录名称。

顺便说一句，你的 findRes/2 函数应该是这样的：

%%% I don't know what work you expect from this function so if it's not working
%%% just like your own, try to fix it!  

% findRes -> find_res
find_res(BddTree, Map) when is_record(BddTree, node) ->
  % Sounds like BddTree is a record. If by `get_name/1` you just want to
  % access one of it's elements, you can simply write BddTree#node.<ELEMENT_NAME>
  % getName -> get_name
  case get_name(BddTree) of
    % you don't have to use ' character for atoms:
    Name when Name == one orelse Name == zero ->
      % I thinkd you've missed `Map`:
      maps:get(get_name(BddTree), Map);
    _ -> 
      % I do not use 0 and 1 and just use boolean type:
      find_res(
        % I thinkd you've missed `Map`:
        case maps:get(get_name(BddTree), Map) of
          Val when Val -> % when Val == true
            % getRight -> get_right
            get_right(BddTree);
          _ -> % Assume false
            get_left(BddTree)
        end,
        Map
      )
  end;

find_res(_, _) -> error.

让我们看看上面没有注释的代码：

find_res(BddTree, Map) when is_record(BddTree, node) ->
  case get_name(BddTree) of
    Name when Name == one orelse Name == zero ->
      maps:get(get_name(BddTree), Map);
    _ -> 
      find_res(
        case maps:get(get_name(BddTree), Map) of
          Val when Val -> % when Val == true
            get_right(BddTree);
          _ ->
            get_left(BddTree)
        end,
        Map
      )
  end;
find_res(_, _) -> error.

守卫中的语法错误导致未定义的函数

Syntax error in a guard causing undefined function

erlang

undefined

guard