基于 return 种类的 Fortran 泛型函数

Question

我正在尝试根据要返回的值在 Fortran 中创建一个通用函数，也就是说，取决于函数的输出是分配给单精度实数还是双精度实数。代码是：

MODULE kk_M

   USE ISO_FORTRAN_ENV

   IMPLICIT NONE

   INTEGER, PARAMETER :: sp = REAL32
   INTEGER, PARAMETER :: dp = REAL64

   INTERFACE use_func
      MODULE PROCEDURE use_sp_func
      MODULE PROCEDURE use_dp_func
   END INTERFACE use_func

   INTERFACE use_sub
      MODULE PROCEDURE use_sp_sub
      MODULE PROCEDURE use_dp_sub
   END INTERFACE use_sub

   CONTAINS

   FUNCTION use_sp_func() RESULT(res)
      REAL(KIND=sp) :: res
      res = 5._sp
   END FUNCTION use_sp_func

   FUNCTION use_dp_func() RESULT(res)
      REAL(KIND=dp) :: res
      res = 5._dp
   END FUNCTION use_dp_func

   SUBROUTINE use_sp_sub(res)
      REAL(KIND=sp), INTENT(OUT) :: res
      res = 5._sp
   END SUBROUTINE use_sp_sub

   SUBROUTINE use_dp_sub(res)
      REAL(KIND=dp), INTENT(OUT) :: res
      res = 5._dp
   END SUBROUTINE use_dp_sub

END MODULE kk_M


PROGRAM kk
   USE kk_M
   IMPLICIT NONE
   REAL(KIND=sp) :: num_sp
   REAL(KIND=dp) :: num_dp

   num_sp = use_func()
   WRITE(*,*) num_sp

   num_dp = use_func()
   WRITE(*,*) num_dp

   CALL use_sub(num_sp)
   WRITE(*,*) num_sp

   CALL use_sub(num_dp)
   WRITE(*,*) num_dp

END PROGRAM kk

使用通用子例程，代码可以编译并运行，但是当我添加通用函数时，它不会编译。我使用 gfortran 收到以下错误消息：

kk.f90:22:3:

    FUNCTION use_sp_func() RESULT(res)                                                                                                                                             
   1
kk.f90:27:3:

    FUNCTION use_dp_func() RESULT(res)                                                                                                                                             
   2
Error: Ambiguous interfaces in generic interface 'use_func' for ‘use_sp_func’ at (1) and ‘use_dp_func’ at (2)
kk.f90:46:7:

    USE kk_M
       1
Fatal Error: Can't open module file ‘kk_m.mod’ for reading at (1): No existe el archivo o el directorio
compilation terminated.

看起来编译器无法根据要返回的值来区分这两个函数。有什么办法可以做到这一点吗？

Answer 1

您无法通过 return 值来区分通用接口中的特定函数。编译器无法查看要使用的 return 值类型。 Fortran 表达式总是在没有周围上下文的情况下求值。 Fortran 通用消歧基于 TKR（类型、种类、等级）解析，仅使用过程参数，而不使用 return 值。

当你有

use_func()

编译器无法知道应该调用这两个函数中的哪一个。即使直接在作业中使用它

 x = use_func()

单独评价。一般来说，函数调用可以出现在各种复杂的表达式中。例如。 use_func(use_func()) + use_func()，哪个会是哪个？

这就是为什么几个内部函数有另一个指定 return 类型的参数的原因。例如，transfer() 函数有第二个参数指定应该 returned 的类型。不然编译器是查不出来的

Answer 2

按照 Vladimir F 的建议，我查看了传递本征函数，并在我的函数中添加了一个模具参数以设置 return 类型。

如果函数的任何输入参数是真实的，它们可用于设置 return 类型，如 High Performace Mark 所述，但由于这不是我的情况，我最终使用了 mold 变量。

现在它可以编译并运行了。代码是：

MODULE kk_M

   USE ISO_FORTRAN_ENV

   IMPLICIT NONE

   INTEGER, PARAMETER :: sp = REAL32
   INTEGER, PARAMETER :: dp = REAL64

   INTERFACE use_func
      MODULE PROCEDURE use_sp_func
      MODULE PROCEDURE use_dp_func
   END INTERFACE use_func

   INTERFACE use_sub
      MODULE PROCEDURE use_sp_sub
      MODULE PROCEDURE use_dp_sub
   END INTERFACE use_sub

   CONTAINS

   FUNCTION use_sp_func(mold) RESULT(res)
      REAL(KIND=sp),INTENT(IN) :: mold
      REAL(KIND=sp) :: res
      IF (.FALSE.) res = mold !To avoid compilation warning about unused variable
      res = 5._sp
   END FUNCTION use_sp_func

   FUNCTION use_dp_func(mold) RESULT(res)
      REAL(KIND=dp),INTENT(IN) :: mold
      REAL(KIND=dp) :: res
      IF (.FALSE.) res = mold !To avoid compilation warning about unused variable
      res = 5._dp
   END FUNCTION use_dp_func

   SUBROUTINE use_sp_sub(res)
      REAL(KIND=sp), INTENT(OUT) :: res
      res = 5._sp
   END SUBROUTINE use_sp_sub

   SUBROUTINE use_dp_sub(res)
      REAL(KIND=dp), INTENT(OUT) :: res
      res = 5._dp
   END SUBROUTINE use_dp_sub

END MODULE kk_M


PROGRAM kk
   USE kk_M
   IMPLICIT NONE
   REAL(KIND=sp) :: num_sp
   REAL(KIND=dp) :: num_dp

   num_sp = use_func(1._sp)
   WRITE(*,*) num_sp

   num_dp = use_func(1._dp)
   WRITE(*,*) num_dp

   CALL use_sub(num_sp)
   WRITE(*,*) num_sp

   CALL use_sub(num_dp)
   WRITE(*,*) num_dp

END PROGRAM kk

基于 return 种类的 Fortran 泛型函数

Fortran generic functions based on the return kind

fortran

function

generic-programming