迭代 (for-loop) ms 访问过去的值

Question

我试图从 VBA excel 翻译一个代码来访问。我的数据是一列价格，我想计算 returns。这是 excel 中的原始 VBA 代码：

DerCol = Cells(T.Row, Columns.Count).End(xlToLeft).Column
Cells(T.Row, DerCol + 1) = "Returns"

For i = T.Row + 2 To T.End(xlDown).Row
    Cells(i, DerCol + 1) = Application.WorksheetFunction.Ln(Cells(i, T.Column)) - Application.WorksheetFunction.Ln(Cells(i - 1, T.Column))
Next i

要了解我在 excel 中的输出，请单击 here。在 Access 中，我在价格列旁边创建了一个新列，我想完全按照 excel:

中的方式填写

Sub vardaily()
    Dim db As Database, T As Object, DerCol As Integer, y As TableDef
    Dim rs As DAO.Recordset, i As Integer, strsql As String

    'idea = SELECT prices FROM dailypricing, then creates newtable "VAR", copy and prices, compute historical and parametric VAR '

    'create a new table var_daily'
    Set db = CurrentDb() 

    'insert the pricing date and the prices from dbo_daily'
    db.Execute "CREATE TABLE VAR_daily" _
                & "(PricingDate CHAR, Price Number);" 

    'where clause to select the same traded product only'
    db.Execute " INSERT INTO VAR_daily " _
                & "SELECT PricingDate, Price " _
                & "FROM dbo_PricingDaily " _
                & "WHERE IndexId = 1;" 

    db.Execute " ALTER TABLE VAR_daily " _
                & "ADD COLUMN Returns Number;"

    'sql request to store prices'       
    strsql = "SELECT First(Price) as FirstPrice, Last(Price) as EndPrice FROM VAR_daily;" 

    'dao.recordset of the store prices'
    Set rs = db.OpenRecordset(strsql, dbOpenDynaset) 

    'loop to change the prices'
    For i = 2 To i = rs.RecordCount 
        rs.Edit
        rs!Price(i) = Log(rs!Price(i)) - Log(rs!Price(i - 1))
        rs.Update
    Next i

    db.Execute "INSERT INTO VAR_daily " _
                & "(Returns) VALUES " _
                & "(" & rs![Price] & ");"
End Sub

我有以下table你可以看到here 我无法处理循环。最后，我的 collection 中没有项目。我查看了 here 等循环的其他示例，但我没有找到如何使用最后的结果进行迭代。

抱歉，我确实是 Ms Access 和 SQL 的初学者。我是这周开始的，所以如果我的问题很基础，我深表歉意。

编辑：我添加了图像并将 Firsttransaction 和 Lasttransaction 替换为 "FirstPrice" 和 "EndPrice"。

EDIT2：感谢我的新特权，我可以与感兴趣的人分享a sample。

Answer 1

我已将您的完整代码更新为应有的样子。同样，我手头没有 Access 数据库来测试它，但它可以编译并且应该可以工作：

Sub vardaily()
    Dim db As Database
    Dim rs As DAO.Recordset, i As Integer, strsql As String
    Dim thisPrice, lastPrice

    'idea = SELECT prices FROM dailypricing, then creates newtable "VAR", copy and prices, compute historical and parametric VAR '

    'create a new table var_daily'
    Set db = CurrentDb()

    'insert the pricing date and the prices from dbo_daily'
    db.Execute "CREATE TABLE VAR_daily" _
                & "(PricingDate CHAR, Price Number);"

    'where clause to select the same traded product only'
    db.Execute " INSERT INTO VAR_daily " _
                & "SELECT PricingDate, Price " _
                & "FROM dbo_PricingDaily " _
                & "WHERE IndexId = 1 " _
                & "ORDER BY PricingDate;"

    db.Execute " ALTER TABLE VAR_daily " _
                & "ADD COLUMN Returns Number;"

    'sql request to retrieve store prices'
    strsql = "SELECT * FROM VAR_daily ORDER BY PricingDate;" ' just get all fields

    'dao.recordset of the store prices'
    Set rs = db.OpenRecordset(strsql, dbOpenDynaset)

    'loop to change the prices'
    lastPrice = rs.Fields("Price")     ' get price from first record and remember
    rs.MoveNext                        ' advance to second record and start loop
    While (Not rs.EOF())
        thisPrice = rs.Fields("Price")
        rs.Edit
            rs!Returns = Log(thisPrice) - Log(lastPrice)
        rs.Update
        lastPrice = thisPrice ' remember previous value
        rs.MoveNext           ' advance to next record
    Wend

End Sub

迭代 (for-loop) ms 访问过去的值

iteration (for-loop) ms Access with past value

iteration

ms-access

vba

for-loop

recordset