将通用 TArray 转换为 varArray

Question

我正在尝试将 array of T 转换为 Variant (varArray)。

对于非泛型类型（即：Integer），我使用以下函数：

function ToVarArray(AValues : array of Integer) : Variant;
var
  i : integer;
begin
  Result := VarArrayCreate(
    [Low(AValues), High(AValues)],
    varInteger
  );

  for i := Low(AValues) to High(AValues) do 
    Result[i] := AValues[i];
end;

我在尝试使用通用 TArray 做同样的事情时遇到了一些问题：

uses
  System.Generics.Collections;

type
  TArray = class(System.Generics.Collections.TArray)
  public
    class function  ToVarArray<T>(const AValues: array of T) : Variant; static;
  end;

我试过以下方法：

class function  TArray.ToVarArray<T>(const AValues: array of T) : Variant;
var
  i : integer;
  Tmp : T;
begin
  Result := Tmp;
  Result := VarArrayCreate(
    [Low(AValues), High(AValues)],
    VarType(Result)
  );

  for i := Low(AValues) to High(AValues) do 
    Result[i] := AValues[i];
end;

但是在我将 T 分配给 Variant 的每一行都会产生以下编译错误：

[dcc32 Error] Unit1.pas(36): E2010 Incompatible types: 'Variant' and 'T'

Answer 1

问题的标题说你想处理泛型 TArray<T>，但第一句说它是 array of T。您可能认为这两个术语指的是相同的数据结构（动态数组），而且大多数时候它们确实如此，但是如果您使用它们代替 procedure/function 参数声明，它们就会有所不同。

因此以下方法具有不同的签名并接受不同类型的参数：

class function TArray.ToVarArray<T>(const AValues: TArray<T>): Variant;
class function TArray.ToVarArray<T>(const AValues: array of T): Variant;

虽然第一个不变量接受真正的动态数组作为参数，但后者为 Delphi 开发人员接受 open array. This unfortunate language design is regular source of confusion。

Delphi RTL 已经包含将动态数组转换为适当类型的变体数组的函数 - DynArrayToVariant。它以指向动态数组初始元素的指针和数组的类型信息作为参数。要使用泛型，您可以这样写：

uses
  System.Variants;

class function TArray.DynArrayToVarArray<T>(const AValues: TArray<T>): Variant;
begin
  DynArrayToVariant(Result, @AValues[0], TypeInfo(TArray<T>));
end;

如果您尝试将此例程与静态数组一起使用，您的代码将无法编译：

var
  SA: array[0..2] of Integer;
begin
  SA[0] := 0;
  SA[1] := 1;
  SA[2] := 2;
  { E2010 Incompatible types: 'System.TArray<System.Integer>' and 'array[0..2] of Integer' }
  TArray.DynArrayToVarArray<Integer>(SA);
end.

开放数组解决了这个问题，但是您需要将它 "convert" 到动态数组以便与 RTL DynArrayToVariant.

一起使用

class function TArray.OpenArrayToVarArray<T>(const AValues: array of T): Variant;
var
  LArray: TArray<T>;
  Index: Integer;
begin
  SetLength(LArray, Length(AValues));
  for Index := Low(AValues) to High(AValues) do
    LArray[Index] := AValues[index];
  Result := DynArrayToVarArray<T>(LArray);
end;

var
  DA: TArray<Integer>;
  SA: array[0..2] of Integer;
begin
  DA := [0, 1, 2];
  SA[0] := 0;
  SA[1] := 1;
  SA[2] := 2;
  { these all work }
  TArray.OpenArrayToVarArray<Integer>(DA); // dynamic array
  TArray.OpenArrayToVarArray<Integer>(SA); // static array
  TArray.OpenArrayToVarArray<Integer>([0, 1, 2]); // open array constructor
end.

上面的OpenArrayToVarArray<T>例程在性能和内存使用方面都非常低效，因为它将元素一个一个地从开放数组复制到动态数组。如果你真的需要支持开放数组，你可能应该编写更好的实现，灵感来自 RTL 的 DynArrayToVariant，但是我发现那个也是 sub-optimal。

将通用 TArray 转换为 varArray

Converting a generic TArray into a varArray

delphi

generics

delphi-xe7

variant