Spring 启动多模块 Gradle 项目类路径问题：找不到包，找不到符号

Question

我在另一个名为 common.[=27= 的项目中有一个 spring 引导 gradle 项目 etl 具有共同核心类的依赖项]

common/build.gradle

plugins {
    id 'net.ltgt.apt' version '0.21'
    id 'org.springframework.boot'
    id 'io.spring.dependency-management'
    id "io.freefair.lombok" version "5.1.0"
    id 'java'
    id 'idea'
    id 'eclipse'
}

group = 'com.intelease'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '1.8'

repositories {
    jcenter()
    mavenCentral()
    maven {
        name "lightbend-maven-release"
        url "https://repo.lightbend.com/lightbend/maven-releases"
    }
    maven {
        name "Sonatype Snapshots"
        url "https://oss.sonatype.org/content/repositories/snapshots/"
    }
    ivy {
        name "lightbend-ivy-release"
        url "https://repo.lightbend.com/lightbend/ivy-releases"
        layout "ivy"
    }
}

dependencies {
    implementation 'com.typesafe.play:play-java_2.13:2.7.3'
    implementation 'com.typesafe.akka:akka-actor-typed_2.13:2.5.23'
    implementation "com.typesafe.play:play-guice_2.12:2.6.15"

    implementation 'org.springframework.boot:spring-boot-starter-data-elasticsearch'
    implementation 'org.springframework.boot:spring-boot-starter-data-mongodb-reactive'

    implementation 'org.neo4j.driver:neo4j-java-driver:1.7.5'
    implementation 'org.apache.poi:poi-ooxml:3.17'
    implementation 'com.google.maps:google-maps-services:0.13.0'
    implementation 'org.apache.commons:commons-text:1.8'
    implementation 'com.google.cloud:google-cloud-language:1.19.0'
    implementation 'com.google.cloud:google-cloud-vision:1.19.0'
    implementation 'technology.tabula:tabula:1.0.2'
    implementation 'com.amazonaws:aws-java-sdk:1.11.618'
    implementation 'edu.stanford.nlp:stanford-corenlp:3.8.0'
    implementation 'nz.ac.waikato.cms.weka:weka-stable:3.8.4'
    // https://mvnrepository.com/artifact/com.typesafe.play/play-java
    implementation 'org.joda:joda-money:0.11'
    implementation 'com.feth:play-easymail_2.12:0.9.0'
    implementation 'com.feth:play-authenticate_2.12:0.9.0'
    implementation 'org.apache.commons:commons-imaging:1.0-alpha1'
    implementation 'com.github.cloudyrock.mongock:mongock-core:3.3.2'
    implementation 'com.github.cloudyrock.mongock:mongock-spring:3.3.2'
    implementation 'net.logstash.logback:logstash-logback-encoder:5.3'
    implementation 'ch.qos.logback:logback-core:1.2.3'
    implementation 'ch.qos.logback:logback-classic:1.2.3'
    implementation 'com.google.firebase:firebase-admin:6.13.0'
    implementation 'org.mapstruct:mapstruct:1.3.1.Final'
    implementation 'org.jgrapht:jgrapht-core:1.4.0'
    implementation 'org.jgrapht:jgrapht-io:1.4.0'
    implementation 'commons-io:commons-io:2.6'
    implementation 'org.springframework.guice:spring-guice:1.1.4.RELEASE'
    implementation 'com.google.inject:guice:4.2.3'
    implementation 'commons-collections:commons-collections:3.2.2'
    implementation 'org.aspectj:aspectjrt:1.9.5'
    implementation 'org.ghost4j:ghost4j:1.0.1'
    annotationProcessor 'org.mapstruct:mapstruct-processor:1.3.1.Final'

    testAnnotationProcessor 'org.mapstruct:mapstruct-processor:1.3.1.Final' // if you are using mapstruct in test code

    testImplementation 'io.projectreactor:reactor-test:3.3.0.RELEASE'
    testImplementation 'org.springframework.boot:spring-boot-starter-test:2.2.0.RELEASE'
    testImplementation 'cloud.localstack:localstack-utils:0.1.22'
    testImplementation 'nl.jqno.equalsverifier:equalsverifier:3.3'
    testImplementation 'net.aichler:jupiter-interface:0.8.3'
    testImplementation 'org.mockito:mockito-junit-jupiter:3.0.0'
    testImplementation 'org.assertj:assertj-core:3.13.2'
    testImplementation 'org.junit.jupiter:junit-jupiter-params:5.5.2'
}

etl/settings.gradle:

rootProject.name = 'etl'

includeFlat ('common')

etl/build.gradle:

plugins {
    id 'org.springframework.boot' version '2.2.7.RELEASE'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
    id 'eclipse'
    id 'idea'
    id 'java'
}

group = 'com.intelease'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '1.8'

repositories {
    mavenCentral()
    jcenter()
    maven {
        name "lightbend-maven-release"
        url "https://repo.lightbend.com/lightbend/maven-releases"
    }
    ivy {
        name "lightbend-ivy-release"
        url "https://repo.lightbend.com/lightbend/ivy-releases"
        layout "ivy"
    }
}

ext {
    set('springCloudVersion', "Hoxton.SR4")
}

dependencies {
    implementation project(':common')
    implementation 'org.apache.kafka:kafka-streams'
    implementation 'io.debezium:debezium-core:1.1.1.Final'
    implementation 'org.springframework.cloud:spring-cloud-stream'
    implementation 'org.springframework.cloud:spring-cloud-stream-binder-kafka-streams'
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }


    testImplementation 'org.springframework.cloud:spring-cloud-stream-test-support'
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
    }
}

test {
    useJUnitPlatform()
}

etl项目和common项目在文件系统中处于同一级别。

问题是，每当我尝试构建依赖于 common 的 etl 项目时，它会显示一些关于类的问题，我预计会带来这些问题并且可从 common 项目获得。

我使用 includeFlat 将 common 包含在 etl 项目中的 settings.gradle 中，并且无法追踪任何关于 gradle multi 的问题模块包含机制。

这个扁平的多模块生态系统有什么问题？

构建脚本在 etl 文件夹中 ./gradlew clean build。

Answer 1

问题是因为 spring 引导插件存在于 etl 和 common 项目中。所以我发现在 cammon/build.gradle 中我必须添加这段代码：

...

bootJar {
    enabled = false
}

jar {
    enabled = true
}

...

Spring 启动多模块 Gradle 项目类路径问题：找不到包，找不到符号

Spring Boot Multi Module Gradle Project classpath problem: Package Not Found, Symbol not Found

gradle

multi-module

spring-boot