根据另一个单元格的列内容更改单元格的值 google sheet

Question

我有一个 Google sheet，其中包含相关信息，我正在尝试使其自动化一些。如果另一个 sheet 的列中有特定字符串，我需要一个将单元格值更改为 Yes 的公式。我使用 IF 和 importrange 尝试了几种不同的方法，但它就是不起作用。

我创建了一个示例 sheet 来展示我正在尝试做的事情： Test Sheet 1 Test Sheet 2

如果 sheet 的第 1 列和第 2 列匹配并且 Sheet 2 的 C 列包含 [=20=，我希望 Sheet 1 的 C 列更改为是] 或 "Yes"。

Answer 1

给你：

={
  "Complete";
  ARRAYFORMULA(
    IF(
        (IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!A2:A") = A2:A)
      * (IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!B2:B") = B2:B)
      * (REGEXMATCH(IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!C2:C"), "Reloaded|Yes")),
        "Yes",
        ""
    )
  )
}

Answer 2

尝试：

=ARRAYFORMULA(IF(REGEXMATCH(VLOOKUP(A2:A&B2:B, {
 IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!A2:A")&
 IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!B2:B"), 
 IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!C2:C")}, 2, 0), 
 "Yes|Reloaded")=TRUE, "Yes", ))

更新：

=ARRAYFORMULA(IFERROR(IF((D2:D="User Task")*(REGEXMATCH(VLOOKUP(B2:B, {
 IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!B2:B"), 
 IMPORTRANGE("1YMBUYC6JgQke-2YWs_VZx9zqlmOdhV8WYvhTpTVxBYM", "Sheet1!C2:C")}, 2, 0), 
 "Yes|Reloaded")=TRUE), "Yes", )))

根据另一个单元格的列内容更改单元格的值 google sheet

Change value of a cell depending on contents of column of another google sheet

if-statement

google-sheets

google-sheets-formula

array-formulas

gs-vlookup

更新：