使用 Cmake 在 Qt Creator 中显示头文件

Question

所以我刚刚使用 Qt Creator 设置了一个新的 Cmake 项目。然后我在项目中添加了一些类，Qt Creator 显示的文件如下：

项目文件夹
- 项目名称
  - 源文件
- 头文件

现在，当我仅添加头文件（新建文件 > C++ 头文件）时（没有源文件），头文件不会显示在 Qt 的项目树中Creator 显示（我在 Header Files 下找不到它）。我可以看到正在创建头文件（使用 Ctrl+K），但它没有显示在头文件下。我读过另一个问题 here 但提供的主要答案并没有真正回答问题。

我的 CMakeslist.txt 如下所示：

cmake_minimum_required(VERSION 3.5)

project(TEST LANGUAGES CXX)

set(CMAKE_INCLUDE_CURRENT_DIR ON)

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# QtCreator supports the following variables for Android, which are identical to qmake Android variables.
# Check http://doc.qt.io/qt-5/deployment-android.html for more information.
# They need to be set before the find_package(Qt5 ...) call.

#if(ANDROID)
#    set(ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android")
#    if (ANDROID_ABI STREQUAL "armeabi-v7a")
#        set(ANDROID_EXTRA_LIBS
#            ${CMAKE_CURRENT_SOURCE_DIR}/path/to/libcrypto.so
#            ${CMAKE_CURRENT_SOURCE_DIR}/path/to/libssl.so)
#    endif()
#endif()


find_package(Qt5 COMPONENTS Core Quick REQUIRED)

if(ANDROID)
    add_library(TEST SHARED
      main.cpp
      wetcanvas.cpp
      wetrenderer.cpp
      qml.qrc
    )
else()
    add_executable(TEST
      main.cpp
      wetcanvas.cpp
      wetrenderer.cpp
      qml.qrc
    )
endif()

target_compile_definitions(TEST
  PRIVATE $<$<OR:$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>:QT_QML_DEBUG>)
target_link_libraries(TEST
  PRIVATE Qt5::Core Qt5::Quick)

Answer 1

您需要将 header 添加到 CMake 的源列表中。你的情况

if(ANDROID)
    add_library(TEST SHARED
      main.cpp
      wetcanvas.cpp
      wetrenderer.cpp
      MyHeader.h
      qml.qrc
    )
else()
    add_executable(TEST
      main.cpp
      wetcanvas.cpp
      wetrenderer.cpp
      MyHeader.h
      qml.qrc
    )
endif()

提示：您可能需要考虑将您的来源放在它们自己的变量中，如下所示：

      set(COMMON_SRC
          main.cpp
          wetcanvas.cpp
          wetrenderer.cpp
          MyHeader.h
          qml.qrc
      )
      set(ANDROID_SRC
          AndroidSpecific.cpp
          AndroidSpecific.h
      )

      if(ANDROID)
        add_library(TEST SHARED
          ${COMMON_SRC}
          ${ANDROID_SRC}
        )   
    else()
        add_executable(TEST
         ${COMMON_SRC}
        )
    endif()

当项目变得更复杂时，它会得到回报。

使用 Cmake 在 Qt Creator 中显示头文件

Display header files in Qt Creator using Cmake

c++

qt

cmake

qt-creator