将列表 1 中的特定数字与列表 2 中的特定数字交换

Question

我最近一直在复习一些序言。我有点喜欢随机提出问题来尝试解决，然后解决它们。不过这个难度很大，我不会放弃我已经着手解决的问题。

问题：我想做一个谓词，有2个预定列表，2个数字要交换，然后在交换完成后输出列表。

进一步的解释：我想从列表 1 中找到一个特定的唯一编号，并将其与列表 2 中的一个特定的唯一编号交换，所以我对自己有点困难如果我有 2 个列表... [7,2,7,8,5] 和 [1,2,3,8,7,9,8]，然后给谓词 2 个数字（我们只说 8 和 7），然后是数字 8 和数字 7 将在列表之间交换 IF 且仅当 数字 8 在第一个列表中而数字 7 在第二个列表中时。（它将忽略第二个列表中的 8 和第一个列表中的 7）。

带有预期答案的示例查询：

?- bothSwap([7,2,7,8,5],[1,2,3,8,7,9,8],8,7,X,Y).
X = [7,2,7,7,5], Y = [1,2,3,8,8,9,8].

我有点卡在这一点上了：

bothSwap([],L2,N1,N2,[],L2).
bothSwap(L1,[],N1,N2,L1,[]).
bothSwap([H1|T1],[H2|T2],N1,N2,X,Y) :- H1 == N1, H2 == N2, bothSwap(T1,T2,N1,N2,D1,D2), append(D1,[H2],X), append(D2,[H1],Y).
bothSwap([H1|T1],[H2|T2],N1,N2,X,Y) :- H1 == N1, H2 =\= N2, bothSwap([H1|T1],T2,N1,N2,D1,D2).
bothSwap([H1|T1],[H2|T2],N1,N2,X,Y) :- H1 =\= N1, H2 == N2, bothSwap(T1,[H2|T2],N1,N2,D1,D2).

有好心人愿意和我一起解决这个问题吗？ :)

Answer 1

想象一下，如果我们可以 "wish" 在所需元素出现时拆分列表，这个问题会有多简单，如下所示：

?- splitsies([1,2,3,4,5,6,7,8], 4, Prefix, Suffix).
Prefix = [1, 2, 3],
Suffix = [5, 6, 7, 8] ;

你猜怎么着？ :) append/3 可以做到：

% splitsies is true if X splits list into a prefix/suffix pair.
splitsies(List, X, Start, Finish) :-
    append(Start, [X|Finish], List).

现在问题看起来很简单了！

bothSwap(Left, Right, A, B, AfterLeft, AfterRight) :-
    % break up the inputs
    splitsies(Left,  A, LPre, LPost),
    splitsies(Right, B, RPre, RPost),

    % glue together the outputs (note that A and B are switched)
    splitsies(AfterLeft,  B, LPre, LPost),
    splitsies(AfterRight, A, RPre, RPost).

我不会假装这个解决方案是有效的......但是它太热了，你最好在输入时戴上烤箱手套。哦，看看这个：

?- bothSwap([7,2,7,8,5],[1,2,3,8,7,9,8], X, Y, [7,2,7,7,5], [1,2,3,8,8,9,8]).
X = 8,
Y = 7 ;
false.

Answer 2

让我们开始，你所说的交换是什么意思。

swap(X0,X, S0,S) :-
   if_(X0 = S0, S = X, S = S0).

bothSwap0(Xs0, Ys0, X0,X, Xs,Ys) :-
   maplist(swap(X0,X), Xs0,Xs),
   maplist(swap(X,X0), Ys0,Ys).

if_( C_1, Then_0, Else_0) :-
   call(C_1, Truth),
   functor(Truth,_,0),  % safety check
   ( Truth == true -> Then_0 ; Truth == false, Else_0 ).

=(X, Y, R) :- X == Y, !, R = true.
=(X, Y, R) :- ?=(X, Y), !, R = false. % syntactically different
=(X, Y, R) :- X \= Y, !, R = false. % semantically different
=(X, Y, R) :- R == true, !, X = Y.
=(X, X, true).
=(X, Y, false) :-
   dif(X, Y).

现在您想要一个特定条件 - 目前尚不清楚如何应用它。我看到两种解释：

bothSwap(Xs0, Ys0, X0,X, Xs,Ys) :-
   memberd(X0, Xs0),
   memberd(X, Ys0),
   maplist(swap(X0,X), Xs0,Xs),
   maplist(swap(X,X0), Ys0,Ys).

这意味着如果这两个元素未出现在各自的列表中，bothSwap/6 将失败。

另一种解释可能是您希望列表保持不变。要表达这一点（以纯粹的单调方式）：

bothSwap(Xs0, Ys0, X0,X, Xs,Ys) :-
   if_( ( memberd_t(X0, Xs0), memberd_t(X, Ys0) ),
        ( maplist(swap(X0,X), Xs0,Xs), maplist(swap(X,X0), Ys0,Ys) ),
        ( Xs0 = Xs, Ys0 = Ys) ).

memberd_t(E, Xs, T) :-
   list_memberd(Xs, E, T).

list_memberd([], _, false).
list_memberd([X|Xs], E, T) :-
   if_(E = X, T = true, list_memberd(Xs, E, T) ).

','( A_1, B_1, T) :-
   if_( A_1, call(B_1, T), T = false ).

Answer 3

由于 Prolog 是一种描述性语言（也就是说，我们描述什么构成了解决方案并让 Prolog 解决），如果我正确理解了你的问题陈述，像这样应该就足够了：

both_swap(L1, L2, A, B, S1, S2 ) :- % to do the swap,
  memberchk(A,L1) ,                 % - L1 must contain an A
  memberchk(B,L2) ,                 % - L2 must contain a B
  replace(L1,A,B,S1) ,              % - replace all As in L1 with a B
  replace(L2,B,A,S2)                % - replace all Bs in L2 with an A
  .                                 % Easy!

replace([],_,_,[]) .                % if the list is empty, we're done.
replace([H|T],A,B,[S|Ss]) :-        % otherwise...
  ( H = A -> S=B ; S=H ) ,          % - do the swap (if necessary),
  replace(T,A,B,Ss)                 % - and recurse down
  .                                 % Also easy!

Answer 4

这复制了使用 splitsies/4

的实现

swap_two(A,B,C,D,E,F) :-
    nth0(I1,A,C,L1),
    dif(A,L1),
    nth0(I2,B,D,L2),
    dif(B,L2),
    nth0(I1,E,D,L1),
    nth0(I2,F,C,L2).

将列表 1 中的特定数字与列表 2 中的特定数字交换

Swapping a specific number in list 1 with a specific number in list 2

predicate

list

prolog