从 NodeJs 调用 nim proc

Question

按照此处的文档操作：https://nim-lang.org/docs/backends.html#backends-the-javascript-target

我在fib.nim

中有以下代码

proc fib(a: cint): cint {.exportc.} =
  if a <= 2:
    result = 1
  else:
    result = fib(a - 1) + fib(a - 2)

如果我运行 nim js -o:fib.js fib.nim 然后它编译成 JS。

然后如何运行来自 nodejs 的 fib？在示例中，它是一个 html 文件和一个浏览器，但在节点上，我不知道如何导入 fib 函数。看起来 .js 文件缺少 exports。如何构建 nim 模块以便 nodejs 可以导入它？

Answer 1

我找不到将 nim 模块编译为 js 模块的内置方法。解决方法是导入 module 对象并导出过程。

import jsffi

var module {.importc.}: JsObject

proc fib*(a: cint): cint =
  if a <= 2:
    result = 1
  else:
    result = fib(a - 1) + fib(a - 2)

module.exports.fib = fib

以上可以用宏表示：

import macros, jsfii

var module {.importc.}: JsObject

macro exportjs(body: typed) =
  let bodyName = body.name.strVal
  result = newStmtList(
    body,
    newAssignment(
      newDotExpr(newDotExpr(ident"module", ident"exports"), ident(bodyName)),
      ident(bodyName)
    )
  )

proc fib*(a: cint): cint {.exportjs.} =
  if a <= 2:
    result = 1
  else:
    result = fib(a - 1) + fib(a - 2)

在查找解决方案时出现了这个 repo：https://github.com/nepeckman/jsExport.nim

从 NodeJs 调用 nim proc

calling nim proc from NodeJs

nim-lang