如何使用 awk 检测嵌入的字段名称和重新排序字段？

Question

我有以下数据：

"b":1.14105,"a":1.14106,"x":48,"t":1594771200000
"a":1.141,"b":1.14099,"x":48,"t":1594771206000
...

我正在尝试按给定顺序显示数据，并且只显示三个字段。由于不能保证字段顺序，我需要为每一行的每个逗号分隔列读取“标签”。

我尝试使用 awk:

来解决这个任务

awk -F',' '
                {
                        for(i=1; i<=$NF; i++) {
                                if(index($i,"\"a\":")!=0) a=$i;
                                if(index($i,"\"b\":")!=0) b=$i;
                                if(index($i,"\"t\":")!=0) t=$i;
                        }
                        printf("%s,%s,%s\n",a,b,t);
                }
        '

但我得到：

,,
,,
...

在上面的数据样本中，我预计：

"a":1.14106,"b":1.14105,"t":1594771200000
"a":1.141,"b":1.14099,"t":1594771206000
...

注意：我使用的是 FreeBSD 附带的 awk

Answer 1

使用 awk 和一个数组：

awk -F '[:,]' '{for(i=1; i<=NF; i=i+2){a[$i]=$(i+1)}; print "\"a\":" a["\"a\""] ",\"b\":" a["\"b\""] ",\"t\":" a["\"t\""]}' file

或

awk -F '[":,]' '{for(i=2; i<=NF; i=i+4){a[$i]=$(i+2)}; print "\"a\":" a["a"] ",\"b\":" a["b"] ",\"t\":" a["t"]}' file

输出：

"a":1.14106,"b":1.14105,"t":1594771200000
"a":1.141,"b":1.14099,"t":1594771206000

Answer 2

类似awk，您可以在其中指定字段和顺序。

$ awk -F[:,] -v fields='"a","b","t"' 'BEGIN{n=split(fields,f)} 
            {for(i=1;i<NF;i+=2) map[$i]=$(i+1); 
             for(i=1;i<=n;i++) printf "%s", f[i]":"map[f[i]] (i==n?ORS:",")}' file

"a":1.14106,"b":1.14105,"t":1594771200000
"a":1.141,"b":1.14099,"t":1594771206000

Answer 3

$ cat tst.awk
BEGIN {
    FS = "[,:]"
    OFS = ","
}
{
    for (i=1; i<NF; i+=2) {
        f[$i] = $(i+1)
    }
    print p("a"), p("b"), p("t")
}

function p(tag, t) {
    t = "\"" tag "\""
    return t ":" f[t]
}

.

$ awk -f tst.awk file
"a":1.14106,"b":1.14105,"t":1594771200000
"a":1.141,"b":1.14099,"t":1594771206000

如何使用 awk 检测嵌入的字段名称和重新排序字段？

How do I detect embbeded field names and reorder fields using awk?

regex

awk

freebsd