如何解决这种类型不匹配？

Question

所以我正在努力将我的 build.gradle（使用 Groovy）转换为 build.gradle.kts（使用 Kotlin），这是我到目前为止得到的：

Groovy原文：

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.3.72'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
}
group 'com.smushytaco'
version '1.0-SNAPSHOT'
repositories {
    mavenCentral()
    maven {
        url 'https://papermc.io/repo/repository/maven-public/'
    }
}
dependencies {
    implementation group: 'org.jetbrains.kotlin', name: 'kotlin-stdlib', version: '1.3.72'
    //https://papermc.io/javadocs/paper/1.16/overview-summary.html
    compileOnly group: 'com.destroystokyo.paper', name: 'paper-api', version: '1.16.1-R0.1-SNAPSHOT'
}
shadowJar {
    getArchiveClassifier().set('')
    project.configurations.implementation.canBeResolved = true
    configurations = [project.configurations.implementation]
    relocate 'kotlin', 'com.smushytaco.src.main.kotlin.com.smushytaco.plugin'
}
build.dependsOn shadowJar

Kotlin 转换：

plugins {
    java
    kotlin("jvm") version("1.3.72")
    id("com.github.johnrengelman.shadow") version("5.2.0")
}
group = "com.smushytaco"
version = "1.0-SNAPSHOT"
repositories {
    mavenCentral()
    maven("https://papermc.io/repo/repository/maven-public/")
}
dependencies {
    implementation("org.jetbrains.kotlin", "kotlin-stdlib", "1.3.72")
    //https://papermc.io/javadocs/paper/1.16/overview-summary.html
    compileOnly("com.destroystokyo.paper", "paper-api", "1.16.1-R0.1-SNAPSHOT")
}
tasks {
    shadowJar {
        archiveClassifier.set("")
        project.configurations.implementation.get().isCanBeResolved = true
        // Type Mismatch:
        // Required: (Mutable)List<Configuration!>!
        //Found: Array<NamedDomainObjectProvider<Configuration>>
        configurations = [project.configurations.implementation]
        relocate("kotlin", "com.smushytaco.src.main.kotlin.com.smushytaco.plugin")
    }
    build {
        dependsOn(shadowJar)
    }
}

我评论了我在 Kotlin 重写时遇到的错误，为什么它适用于原始 Groovy 而不是这个？我该如何解决这个错误？

Answer 1

使用这个：

configurations = listOf(project.configurations.implementation.get())

如何解决这种类型不匹配？

How Do I Resolve This Type Mismatch?

groovy

gradle

kotlin

gradle-kotlin-dsl