有没有办法模拟 Vimscript/VimL 函数？

Question

我很想知道是否有任何方法可以模拟 Vimscript 函数以进行测试。我知道有像 vader.vim 这样的框架，但没有提到模拟。

Answer 1

您可以使用 :function! 重新定义任何现有的用户函数。所以，例如，

function! Mock(name, Hook) abort
    " save a reference to original function
    let l:Orig = funcref(a:name)
" overwrite function
let l:text =<< trim EOF
        function! %s(...) abort closure
            let l:oldresult = call(l:Orig, a:000)
            let l:newresult = call(a:Hook, [l:Orig, l:oldresult] + a:000)
            return l:newresult isnot v:null ? l:newresult : l:oldresult
        endfunction
EOF
    execute printf(join(l:text, "\n"), a:name)
endfunction

" silly test
function! Test(p1, p2) abort
    return a:p1 * a:p2
endfunction

function! MyHook(Orig, result, ...) abort
    echo 'Calling' get(a:Orig, 'name') 'with params' a:000 'produced' a:result
    " remember: default return value is zero, not v:null
    return a:result * 2
endfunction

call Mock('Test', funcref('MyHook'))
echo Test(6, 7)

" Calling Test with params [6, 7] produced 42
" 84

有没有办法模拟 Vimscript/VimL 函数？

Is there a way to mock Vimscript/VimL functions?

vim

vim-plugin