计算 xslt 1.0 中逗号分隔值中的唯一值

Question

我在 XML 文件中有一个节点：

<TEST_STRING>12,13,12,14</TEST_STRING>

我需要计算这个字符串有多少个 numbers/values。例如，在这种情况下，有 2 个唯一值，即 13 和 14。

老实说，我还不能构建任何东西。在 XSLT 1.0 中似乎很难，但我的系统只支持 1.0.

有什么解决办法吗？

Answer 1

如果您的处理器支持 node-set 扩展函数（exslt or the Microsoft msxsl one），那么您可以分两步完成，首先拆分字符串并构建一个包含一个元素的 XML 片段每个值，然后使用普通的 XPath 技术来查找单例。

第一步可以用尾递归模板完成：

<xsl:template name="splitString">
  <xsl:param name="str"/>
  <xsl:choose>
    <xsl:when test="contains($str, ',')">
      <item><xsl:value-of select="substring-before($str, ',')"/></item>
      <xsl:call-template name="splitString">
        <xsl:with-param name="str" select="substring-after($str, ',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <item><xsl:value-of select="$str"/></item>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

在适当的地方你可以称它为

<xsl:variable name="itemsRTF">
  <xsl:call-template name="splitString">
    <xsl:with-param name="str" select="TEST_STRING"/>
  </xsl:call-template>
</xsl:variable>
<xsl:variable name="items" select="exsl:node-set($itemsRTF)"/>

items 变量现在包含 XML 的片段，如

<item>12</item>
<item>13</item>
<item>12</item>
<item>14</item>

下一个挑战是找到单例，你可以用像

这样的表达式来完成

$items/item[not(. = (preceding-sibling::item | following-sibling::item))]

（使用 key 有更有效的方法，但对于少量项目，可能不值得这么麻烦）。所以算上单身人士

<xsl:value-of select="count($items/item[not(. = (preceding-sibling::item | following-sibling::item))])"/>

Answer 2

没有节点集也是可能的。这当然不是最佳选择（你好，Shlemiel The Painter），但它非常简单 - 仅当前面或后面没有给定字符串时才增加计数器。

模板

<xsl:template name="calcUnique">
    <xsl:param name="str"/>
    <xsl:param name="back"/>
    <xsl:param name="count"/>

    <xsl:if test="$str">
        <xsl:choose>
            <xsl:when test="contains($str, ',')">
                <xsl:variable name="part" select="substring-before($str, ',')"/>
                <xsl:call-template name="calcUnique">
                    <xsl:with-param name="str" select="substring-after($str, ',')"/>
                    <xsl:with-param name="back" select="concat($back, ',', $part)"/>
                    <xsl:with-param name="count">
                        <xsl:choose>
                            <xsl:when test="contains(concat($str, ','), concat(',', $part, ',')) or contains(concat($back, ','), concat(',', $part, ','))">
                                <xsl:value-of select="$count"/>
                            </xsl:when>
                            <xsl:otherwise><xsl:value-of select="$count + 1"/></xsl:otherwise>
                        </xsl:choose>
                    </xsl:with-param>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:choose>
                    <xsl:when test="contains(concat($back, ','), concat(',', $str, ','))">
                        <xsl:value-of select="$count"/>
                    </xsl:when>
                    <xsl:otherwise><xsl:value-of select="$count + 1"/></xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:if>
</xsl:template>

示例用法

    <xsl:variable name="result">
        <xsl:call-template name="calc">
            <xsl:with-param name="str" select="TEST_STRING"/>
            <xsl:with-param name="back" select="''"/>
            <xsl:with-param name="count" select="0"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:value-of select="$result"/>

计算 xslt 1.0 中逗号分隔值中的唯一值

Count unique values in comma separated value in xslt 1.0

xslt

xpath

xslt-1.0