Fortran 接口调用 C 函数，returns 一个指向数组的指针

Question

经过大量搜索，我发现我认为最接近我的问题的答案是 Fortran interface to call a C function that return a pointer 上的 Stack Overflow (SO)，（将近 10 年前发布！）

我引用这个是因为使用该示例可以使代码简单并且仍然可以说明我的问题。

我想要 return 一个已经 created/memory 在 C++ 中分配的数组，并且能够在 Fortran 中分析答案，因为这是该应用程序的大部分代码所在的位置。我的应用程序进入 C++ 以生成整数数组答案，并通过 C 接口 return 将其发送到 Fortran 程序。原始 SO 示例使用单个双精度变量作为 return。我已将其更改为整数，因为这是我将在我的应用程序中处理的内容。示例代码（已更改）有效。

我已经用评论突出显示了我试图对 return 数组指针所做的更改，但我运行没有想法。（我可以说，“哦，在过去糟糕的日子里，我可以将一个整数等价于一个 iarray(1) 并超出数组的大小”，但我不会。有编码保护是件好事，但有时令人沮丧。）

我正在使用 Visual Studio 2017 和 Intel Fortran parallel_studio_xe_2019_update5_composer。

我对原SO代码的修改示例：

! ps_test_pointers.f90

program foo
  use, intrinsic :: iso_c_binding, only : c_ptr,        &
                                          c_f_pointer,  &
                                          c_int
  implicit none
  type(c_ptr) :: c_p!(:) ! <-------
  integer(c_int), pointer :: f_p!(:) ! <-------

  interface
    function foofunc() bind(c)
      import :: c_ptr
      implicit none  
      type(c_ptr) :: foofunc!(:) ! <-------
    end function foofunc
  end interface

  c_p = foofunc()
  call c_f_pointer(c_p, f_p)
  print *, f_p

end program foo

// ps_test_pointersC.cpp : 'Subroutine' only.

extern "C" {

    int bar[3] = { 2, 3, 4 };
    
    int *foofunc() {
        return bar;
    }

}

正如我上面所说，代码有效，因为它打印出数组的第一个元素 (‘2’)。

如果我将“(:)”添加到 f_p 的定义中，代码编译没有错误，但是当我运行它时，程序失败并显示运行 -时间错误：“forrtl: severe (408): fort: (7): 尝试使用指针 F_P 当它与目标无关时” 在行 “call c_f_pointer(c_p, f_p)".

我尝试将 c_p 声明为数组（“c_p(:)”），但我在同一个地方遇到了同样的错误。

我也试过调用 c_p 作为子程序的参数——仍然只使用整数：

    ! ps_test_pointers.f90
    
    program foo
      use, intrinsic :: iso_c_binding, only : c_ptr,        &
                                              c_f_pointer,  &
                                              c_int
      implicit none
      type(c_ptr) :: c_p!(:) ! <-------
      integer(c_int), pointer :: f_p!(:) ! <-------
    
      interface
        subroutine foofunc(c_p) bind(c)
          import :: c_ptr
          implicit none  
          type(c_ptr) :: c_p!(:) ! <-------
        end subroutine foofunc
      end interface
    
      call foofunc(c_p)
      call c_f_pointer(c_p, f_p)
      print *, f_p
    
    end program foo

    // ps_test_pointersC.cpp : 'Subroutine' only.
    
    extern "C" {
    
        int bar[3] = { 2, 3, 4 };
        
        void foofunc(int *rtn) {
            rtn = bar;
        }
    
    }

但 C 函数中创建的指针从未在 return 上分配给 c_p（因此从未定义 f_p）。

阅读这个问题，我希望我没有处于编译器实现的最前沿，并且暴露了限制收紧与无法应对所有用例之间的问题！

有解决办法吗？

Answer 1

您的 C 函数正在返回一个指针标量；您希望将此目标与 Fortran 数组相关联。这意味着您有声明

type(c_ptr) :: c_p                  ! <- scalar address
integer(c_int), pointer :: f_p(:)   ! <- array to associate

在对 c_f_pointer 的调用中，您使用另一个参数指定了 Fortran 指针数组的形状。但是，在这种情况下，Fortran 端无法知道 C 函数返回的数组有多大。

考虑：

use, intrinsic :: iso_c_binding
implicit none

type(c_ptr) :: c_p
integer(c_int), pointer :: f_p(:)

interface
    function foofunc() bind(c)
      import :: c_ptr
      implicit none  
      type(c_ptr) :: foofunc
    end function foofunc
end interface

c_p = foofunc()
call c_f_pointer(c_p, f_p, [3])
print *, f_p

end

如果您不喜欢幻数 3，您将需要找到一些其他方法来获取该数字（就像在 C 世界中调用此函数一样）。您可以将长度作为额外参数，如示例，作为链接关联的额外变量，通过单独的查询调用（例如如何使用字符数组 strnlen）等.

或者，如果您想要非常花哨并且在语言接口方面具有灵活性，则可以在 C 子例程中使用“改进的互操作性”功能来进行 Fortran 内存管理：

program foo
  use, intrinsic :: iso_c_binding, only : c_int

  implicit none
  integer(c_int), pointer :: f_p(:)

  interface
     subroutine foosub(f_p) bind(c)
       import c_int
       implicit none  
       integer(c_int), pointer, intent(out) :: f_p(:)
     end subroutine foosub
  end interface
    
  call foosub(f_p)
  print *, f_p
    
end program foo

#include "ISO_Fortran_binding.h"

int bar[3] = { 2, 3, 4 };
        
void foosub(CFI_cdesc_t* f_p) {
  CFI_index_t nbar[1] = {3};
  CFI_CDESC_T(1) c_p;

  CFI_establish((CFI_cdesc_t* )&c_p, bar, CFI_attribute_pointer, CFI_type_int,
                nbar[0]*sizeof(int), 1, nbar);
  CFI_setpointer(f_p, (CFI_cdesc_t *)&c_p, NULL);
}

如果您愿意，也可以使用可分配变量而不是指针变量。

这种方法不适用于 Fortran 函数，因为可互操作的函数不能有数组、指针或可分配的结果。

Answer 2

RE 子例程方法，我认为我们可能需要在 C/C++ 端将 c_p 声明为 int**（而不是 int*）以获得通过参数关联 bar 的地址（而不是函数 return 值）。所以像...

main.f90:

program foo
  use, intrinsic :: iso_c_binding, only : c_ptr,        &
                                          c_f_pointer,  &
                                          c_int
  implicit none
  type(c_ptr) :: c_p
  integer(c_int), pointer :: f_p(:)
  integer(c_int) :: nsize

  interface
    subroutine foosub( c_p, nsize ) bind(c)
      import :: c_ptr, c_int
      implicit none  
      type(c_ptr)    :: c_p    !<-- sends the pointer to c_p
      integer(c_int) :: nsize  !<-- sends the pointer to nsize
    end subroutine
  end interface

  call foosub( c_p, nsize )
  call c_f_pointer( c_p, f_p, [nsize] )

  print *, "nsize  = ", nsize
  print *, "f_p(:) = ", f_p(:)

end program

sub.cpp:

extern "C" {
    int bar[3] = { 2, 3, 4 };
    
    void foosub( int** rtn, int* nsize ) {
        *rtn = bar;
        *nsize = sizeof(bar) / sizeof(int);
    }
 }

编译 & 运行:

$ g++-10 -c sub.cpp
$ gfortran-10 -c main.f90
$ g++-10 main.o sub.o -lgfortran
$ ./a.out
 nsize  =            3
 f_p(:) =            2           3           4

Fortran 接口调用 C 函数，returns 一个指向数组的指针

Fortran interface to call a C function that returns a pointer to an array

arrays

fortran

pointers

interface

fortran-iso-c-binding