将分配的数组从子程序传递到 Fortran 中的主程序；使用或模块？界面？

Question

我想在子程序中分配一个数组，然后在主程序中使用这个数组并将其传递给其他子程序。过去（F77？）传递可以在公共块中完成，但现在更受欢迎的过程似乎是使用模块。当我尝试这样做时，如代码示例中所示，编译器告诉我

Rank mismatch in argument ‘f’ at (1) (scalar and rank-1)

显然，主程序认为 'f' 是一个标量：但是，我读这段代码意味着我已经将它声明为一维数组，无论是在子程序中还是在主程序中程序。我错过了什么？

我已经尝试过各种变体，例如将变量声明为模块的一部分，但我想不出没有什么可以使编译没有错误（有些会产生更多错误 ;-( )）。任何见解都是最重要的赞赏。

          module subs
        contains
        subroutine makef(f)
        end subroutine makef
      end module subs
c-----------------------------------------------------------------------
      program work

      use subs
      implicit none
        real, allocatable :: f(:)

      call makef(f)

      write (*,*) f
      stop
      end
c---------------------------------------------------------------------
      subroutine makef(f)
      implicit none

      real, allocatable, intent(out) :: f(:)
      integer :: i
      integer :: is

      is=10
      allocate(f(-is:is))

      do i=-is,is
        f(i)=i
      end do
      return
      end subroutine makef

Answer 1

您只将第一行和最后一行的副本放入模块中。那是行不通的。您必须将整个子例程移动到模块中。

Answer 2

Fortran 中的模块与其他语言中的头文件不同，后者仅提供有关在其他地方定义的事物的信息。有“延迟定义”（子模块）的概念，但在这种情况下，模块应该说明有关子例程的所有内容，而不仅仅是试图指出它的存在。

在问题的例子中，我们有：主程序；带有模块过程 makef 的模块 subs；外部子程序 makef.

主程序使用模块 subs 及其过程 makef，因此在主程序中引用 makef 是指模块过程而不是外部子例程 makef.

模块子例程 makef 的参数 f 没有声明语句，使其成为隐式声明的 scalar/external 函数。这是编译器的消息。在模块中使用implicit none，就像在主程序和外部子程序中一样。

子例程的整个定义应放在模块中：

module subs
  implicit none
contains
  subroutine makef(f)
    real, allocatable, intent(out) :: f(:)
    integer :: i
    integer :: is

    is=10
    allocate(f(-is:is))

    do i=-is,is
      f(i)=i
    end do
  end subroutine makef
end module subs

或者，如果确实想要引用外部过程的后续实现，则可以在模块中使用接口块，而无需声明子例程本身。在这种情况下，仍然需要指定完整的接口：

module subs
  implicit none

! An interface block to give an explicit interface to the external subroutine makef
  interface
     subroutine makef(f)
       implicit none
       real, allocatable, intent(out) :: f(:)
     end subroutine makef
  end interface
end module subs

在这种情况下，不喜欢界面块。

将分配的数组从子程序传递到 Fortran 中的主程序；使用或模块？界面？

passing allocated array from subroutine to the main program in fortran; use or module? interface?

fortran

gfortran