在循环中释放多个动态创建的帧

Question

我有一个程序，在其中一种形式上，我需要在运行时动态创建未指定数量的帧（由数据库搜索后的记录数决定）。我使用 for 循环完成了此操作，并且为每个新创建的框架分配了一个新名称，如下所示：

for K:=1 to qryAeroAir.RecordCount do
      begin
        frmFlightDisplay:=TfrmFlightDisplay.Create(frmBook);
        frmFlightDisplay.Name:='frmFlightDisplay'+IntToStr(K);
        frmFlightDisplay.Parent:=pnlBookingDisplay;
        // Rest of code for frame properties
      end;

这似乎工作正常，但是稍后在程序中我需要在创建新帧（使用相同类型的循环）之前释放或销毁这些帧，这就是我遇到问题的地方。

for I:=1 to qryAeroAir.RecordCount do
    begin
    TfrmFlightDisplay(FindComponent('frmFlightDisplay'+IntToStr(I))).Free;
    end;

上面的代码给我一个错误 'Frame with the name frmFlightDisplay1' 已经存在，这让我相信框架实际上并没有被破坏。有没有其他方法可以释放或销毁所有帧以防止这种情况发生？

Answer 1

使用字符串操作管理动态创建的对象很脆弱，而且性能不佳。

恕我直言，更好的方法是将帧存储在对象列表中。在您的表单 class 中声明一个私有字段（使用 Generics.Collections）

private
  FFrames: TObjectList<TfrmFlightDisplay>;

并使用以下形式创建和销毁它：

procedure TForm1.FormCreate(Sender: TObject);
begin
  FFrames := TObjectList<TfrmFlightDisplay>.Create(True {owns objects});
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FFrames.Free;
end;

然后，当你创建一个新的框架时，你把它放在这个列表中，然后它就会拥有它：

procedure TForm1.btnAddFlightDisplayClick(Sender: TObject);
var
  frm: TfrmFlightDisplay;
begin
  frm := TfrmFlightDisplay.Create(nil);
  try
    frm.Parent := Self;
    // other code settings properties of frm
  except
    frm.Free;
    raise;
  end;
  FFrames.Add(frm); // transfer of ownership
end;

要释放所有框架，只需将它们从列表中删除即可。由于列表拥有框架，这将释放框架对象：

procedure TForm1.btnClearClick(Sender: TObject);
begin
  FFrames.Clear;
end;

你的代码有什么问题？

但是我还没有解释你的代码有什么问题。

我的猜测是

实际错误消息是“名为 frmFlightDisplay1 的组件已存在”，
异常不是在您尝试删除框架时发生，而是在您尝试再次添加它们时发生，并且
添加和删除框架的代码块不在 frmBook 的方法中。

如果我的猜测是正确的，问题是你明确地让框架归 frmBook 所有（给框架构造函数的参数），但是 FindComponent 是一个 shorthand 对于 Self.FindComponent，如果这不是 frmBook 方法中的运行，则 Self 不是 frmBook。因此，FindComponent 将 return nil 和 Free 将没有效果。（幸运的是，即使 X 是 nil，X.Free 也是安全的。）

因此，快速解决您的问题的方法是改写 frmBook.FindComponent。

在循环中释放多个动态创建的帧

Free multiple dynamically created frames in a loop

delphi

delphi-10.3-rio

你的代码有什么问题？