指针和 PROGMEM 的问题

Question

我在 Arduino UNO 上编程，遇到了一个非常烦人的路障。

我在 PROGMEM 方面遇到了一个非常奇怪的问题，我已将其缩小为指针数组的问题。

当我用变量 j 索引 PROGMEM 数组时。 returns 不同的结果取决于天气变量 j 是由静态数字设置还是由另一个变量设置。

程序编号是一个存储在对象中的整数，仅按如下方式设置，分配内存并且变量保持其值。我已经测试过了。

*(this->program) = 0;

设置j为0直接产生正确的地址

uint16_t j = 0;
Serial.println(j);    
//printed 0 as expected

address = (uint16_t)*(pgmStringTable + (uint16_t)j); 
Serial.println(address);   
//gave address = 105, which is correct and PROGMEM reads the correct bytes

但是，如下使用 progam 变量设置 j 会产生不正确的地址

uint16_t j = *(this->program);
Serial.println(j);    
//printed 0 as expected

address = (uint16_t)*(pgmStringTable + (uint16_t)j); 
Serial.println(address);   
//gave address = 4, which isnt right and results in PROGMEM read errors

甚至试图解决这个集合问题，比如对 *(this->program) 进行一些算术运算，或者将其发送到 returns 相同值的整数永远无济于事的函数。唯一有用的是循环遍历所有整数，如下所示：

//loops through most unsigned integer values
for(uint16_t j = 0; j < 65000; j++){
  if(j == *(this->program)){
     address = (uint16_t)*(pgmStringTable + (uint16_t)j); 
     //address is correct and PROGMEM works correctly
  }
}

以上工作更有理由确认 malloc 工作正常，因为 *(this->program) 在与 j 比较时返回正确的值。

这是一个非常糟糕的解决方法，因为它非常低效，并且会导致我的程序浪费大量周期，这对时间非常敏感。

任何指向解决方案的指针或指针表现有趣的原因都将非常有用。

这个问题来自一个非常大的项目，所以为了帮助缩小错误范围，我在一个小得多的 .ino 文件中重新创建了这个问题

整个代码是这样的。上传我的 arduino UNO

时产生了同样的错误

编辑：

经过进一步调查，将 j 设置为在我的主项目中不是常量的任何变量（因此该变量不能在项目中的任何其他内容中更改）似乎以与描述相同的方式破坏了 PGM。



const char pgmString1[] PROGMEM = "String 1__";
const char pgmString2[] PROGMEM = "2nd String";
const char *const pgmStringTable[] PROGMEM = {pgmString1, pgmString2};




class testObject{

    private:
        uint16_t* program;

    public:


        testObject(){
            program = (uint16_t*) malloc(sizeof(uint16_t));
            *(this->program) = 0;
        }

        void read(){
            if(*(this->program) == 0){
                //the console prints the below, meaning the value is definitly 0
                Serial.println("it was 0");
                *(this->program) = 0;
            }else{
                Serial.println("it wasnt 0");
                
                //if this is uncommeneted, this program outputs the correct values but the above comment will not be dispalyed
                //*(this->program) = 0;
            }

            char temp[10];
            uint16_t j = 0;
            uint16_t address = 0;   

////////////////////////////////////////////// indirectly setting j
            //sets the j value to be 0, which is what is stored in this->program
            j = *(this->program);

            //prints j to make sure its 0, then finds the address of the progmem string
            Serial.print(j);
            Serial.print("  1 Address: |"); 
            address = (uint16_t)*(pgmStringTable + (uint16_t)j);   
            Serial.print(address);     //the address printed is incorrect
            Serial.print("   ");

            //reads byte by byte from the address, it reads the wrong bytes
            for(int i = 0; i < 10; i++){    
                char myChar = pgm_read_byte( address + i );
                Serial.print(myChar);
            }
            Serial.println("\n");
                    
////////////////////////////////////////////// directly setting j
            //but just setting j = 0 works fine
            j=0;

            //so directly setting j as 0, same code as above but it produces the correct output
            //SAME AS ABOVE, COULDNT SEPERATE INTO ITS ONW FUNCTION
            Serial.print(j);
            Serial.print("  2 Address: |");
            address = (uint16_t)*(pgmStringTable + (uint16_t)j);
            Serial.print(address);
            Serial.print("   ");
            for(int i = 0; i < 10; i++){    
                char myChar = pgm_read_byte( address + i );
                Serial.print(myChar);
            }
            Serial.println();
            //

        }
};





testObject pgmReader;

void setup(){
    Serial.begin(9600);
}

void loop(){
    Serial.println("\n\n\n\n\n\n\n\n");
    delay(1000);
    pgmReader.read();

}

Answer 1

不仅pgmString1和pgmString2而且pgmStringTable也是PROGMEM。所以你必须使用 pgm_read_ 函数来读取 pgmStringTable.

address = pgm_read_ptr(pgmStringTable + (uint16_t)j);

指针和 PROGMEM 的问题

issues with pointers and PROGMEM

c++

c

pointers

arduino

progmem