如何设置 Raku sqrt 的精度级别？

Question

使用 Perl，可以使用 bignum 来设置所有运算符的精度级别。如：

use bignum ( p => -50 );

print sqrt(20);    # 4.47213595499957939281834733746255247088123671922305

对于 Raku，我对有理数没有任何问题，因为我可以使用 Rat / FatRat，但我不知道如何为 sqrt

使用更长的精度

say 20.sqrt # 4.47213595499958

Answer 1

在 Rakudo 中，sqrt 是使用 sqrt_n NQP 操作码实现的。这表明它仅支持本机数字（因为 _n 后缀）。这意味着精度有限。

在内部，我很确定这只是映射到 MoarVM 使用的底层数学库之一的 sqrt 功能。

我想我们需要的是一个生态系统模块，它可以导出一个基于 Rational 算法的 sqrt 函数。这将使您可以选择以牺牲性能为代价使用更高精度 sqrt 实现。反过来，这可能会变得足够有趣，可以集成到核心中。

Answer 2

正如伊丽莎白的回答所述，sqrt returns 是一种 Num 类型，因此精度有限。有关详细信息，请参阅伊丽莎白的。

出于这个原因，我创建了一个 raku class: BigRoot，它使用牛顿法和 FatRat 类型来计算根。你可以这样使用它：

use BigRoot;

# Can change precision level (Default precision is 30)
BigRoot.precision = 50;

my $root2 = BigRoot.newton's-sqrt: 2;
# 1.41421356237309504880168872420969807856967187537695

say $root2.WHAT;
# (FatRat)

# Can use other root numbers
say BigRoot.newton's-root: root => 3, number => 30;
# 3.10723250595385886687766242752238636285490682906742

# Numbers can be Int, Rational and Num:
say BigRoot.newton's-sqrt: 2.123;
# 1.45705181788431944566113502812562734420538186940001

# Can use other rational roots
say BigRoot.newton's-root: root => FatRat.new(2, 3), number => 30;
# 164.31676725154983403709093484024064018582340849939498

# Results are rounded:

BigRoot.precision = 8;
say BigRoot.newton's-sqrt: 2;
# 1.41421356

BigRoot.precision = 7;
say BigRoot.newton's-sqrt: 2;
# 1.4142136

总的来说它似乎相当快（至少与 Perl 的 bigfloat 相比）

基准：

|---------------------------------------|-------------|------------|
|  sqrt with 10_000 precision digits    |    Raku     |    Perl    |
|---------------------------------------|-------------|------------|
|  20000000000                          |    0.714    |   3.713    |
|---------------------------------------|-------------|------------|
|  200000.1234                          |    1.078    |   4.269    |
|---------------------------------------|-------------|------------|
|  π                                    |    0.879    |   3.677    |
|---------------------------------------|-------------|------------|
|  123.9/12.29                          |    0.871    |   9.667    |
|---------------------------------------|-------------|------------|
|  999999999999999999999999999999999    |    1.208    |   3.937    |
|---------------------------------------|-------------|------------|
|  302187301.3727 / 123.30219380928137  |    1.528    |   7.587    |
|---------------------------------------|-------------|------------|
|  2 + 999999999999 ** 10               |    2.193    |   3.616    |
|---------------------------------------|-------------|------------|
|  91200937373737999999997301.3727 / π  |    1.076    |   7.419    |
|---------------------------------------|-------------|------------|

如果想使用牛顿法实现您自己的sqrt，这是它背后的基本思想：

sub newtons-sqrt(:$number, :$precision) returns FatRat {
    my FatRat $error = FatRat.new: 1, 10 ** ($precision + 1);
    my FatRat $guess = (sqrt $number).FatRat;
    my FatRat $input = $number.FatRat;
    my FatRat $diff = $input;

    while $diff > $error {
        my FatRat $new-guess = $guess - (($guess ** 2 - $input) / (2 * $guess));
        $diff = abs($new-guess - $guess);
        $guess = $new-guess;
    }

    return $guess.round: FatRat.new: 1, 10 ** $precision;
}

如何设置 Raku sqrt 的精度级别？

How can I set the level of precision for Raku's sqrt?

perl

raku

sqrt

arbitrary-precision