如何根据 Google 工作表中的列表使用 2 层数据验证来切换 b/w 查询

Question

我正在尝试创建一个依赖于数据验证和查询的 2 层报告 2（除非你告诉我查询在这里不起作用，我应该使用其他功能）。

这是 sheet 的视觉效果。包括对每个值的查询 return 我在 A8 中想要的结果。我计划使用条件格式，以便隐藏 B2，除非 A2=ECR。在一个完美的世界中，当 ECR 在 A2 中被 select 编辑时，B2 将默认为“ALL”，但这并不是什么大问题 - 如果它是空白的，一个人可以 select 全部。

以下是每一层中的值以及它们将要进行的查询运行。

第 1 层：A2

 - ADP  =QUERY(GlobalAVG!H2:L78,"select H,L",1) (value in tier 2 would be ignored)
 - ECR  (use tier 2)

第 2 层：B2

 - ALL  =QUERY(GlobalAVG!O2:S78,"select O,S",1)
 - QB   =QUERY(GlobalAVG!AA2:AE78,"select AA,AE",1)
 - RB   =QUERY(GlobalAVG!AG2:AK78, "select AG,AK",1)
 - WR   =QUERY(GlobalAVG!AM2:AQ78, "select AM,AQ",1)
 - TE   =QUERY(GlobalAVG!AS2:AW78, "select AS,AW",1)
 - K    =QUERY(GlobalAVG!AY3:BC78, "select AY,BC")

我已经尝试了一些方法，但甚至无法让第一层交换机工作。我做错了什么？

=iferror(
    IFS(A2="ADP",
             QUERY(GlobalAVG!H2:L78,"select H,L",1),
         A2="ECR",
            QUERY(GlobalAVG!O2:S78,"select O,S",1))
,"NO RESULTS")

这只是 return 一个单元格，但似乎“有效”，因为当 A2 为空白时，会发布“无结果”。

Answer 1

尝试：

=IF(A2="ADP",  QUERY(GlobalAVG!H2:L78,   "select H,L",   1), 
 IF(B2="ALL",  QUERY(GlobalAVG!O2:S78,   "select O,S",   1),
 IF(B2="QB",   QUERY(GlobalAVG!AA2:AE78, "select AA,AE", 1),
 IF(B2="RB",   QUERY(GlobalAVG!AG2:AK78, "select AG,AK", 1),
 IF(B2="WR",   QUERY(GlobalAVG!AM2:AQ78, "select AM,AQ", 1),
 IF(B2="TE",   QUERY(GlobalAVG!AS2:AW78, "select AS,AW", 1),
 IF(B2="K",    QUERY(GlobalAVG!AY3:BC78, "select AY,BC", 1), 
 "NO RESULTS"))))))

更新：

=IFERROR(
 IF(A2="ADP",  QUERY(GlobalAVG!H2:L78,   "select H,L",   1), 
 IF(B2="ALL",  QUERY(GlobalAVG!O2:S78,   "select O,S",   1),
 IF(B2="QB",   QUERY(GlobalAVG!AA2:AE78, "select AA,AE", 1),
 IF(B2="RB",   QUERY(GlobalAVG!AG2:AK78, "select AG,AK", 1),
 IF(B2="WR",   QUERY(GlobalAVG!AM2:AQ78, "select AM,AQ", 1),
 IF(B2="TE",   QUERY(GlobalAVG!AS2:AW78, "select AS,AW", 1),
 IF(B2="K",    QUERY(GlobalAVG!AY3:BC78, "select AY,BC", 1), 
               QUERY(GlobalAVG!O2:S78,   "select O,S",   1))))))), 
 "NO RESULTS")

如何根据 Google 工作表中的列表使用 2 层数据验证来切换 b/w 查询

How do I switch b/w queries using 2 tiered data validation based on lists in Google Sheets

if-statement

google-sheets

google-sheets-formula

google-sheets-query

更新：