迭代器的通用可变和不可变参数

Question

这是一个我不想复制的迭代器：

iterator testI[T](arr: seq[T]): T =
  # I don't want to copy-paste this body
  # In a real world example it might be much bigger
  for i in 0 ..< arr.len:
    yield arr[i]

这适用于：

for i in testI(@[1,2,3]):
  echo i

但不在：

var lst = @[1,2,3]
for i in testI(lst):
  i += 1
  echo i

我可以将迭代器定义替换为：

iterator testI[T](arr: var seq[T]): var T =
  # I don't want to copy-paste this body
  # In a real world example it might be much bigger
  for i in 0 ..< arr.len:
    yield arr[i]

注意我刚刚将 var 添加到参数和 return。但这使得它不再适用于上面的非 var 情况。

据我所知，这个问题等同于完成以下工作：

proc foo[A, B](x: A, fn: B) =
  fn(x)

var x = 1
foo(x, proc(x: var int) = x += 1)
foo(1, proc(x: int) = echo x)
assert x != 1

出于某种原因，这甚至不起作用：

iterator testI[A, B](arr: A): B =
  # I don't want to copy-paste this body
  # In a real world example it might be much bigger
  for i in 0 ..< arr.len:
    yield arr[i]
var lst = @[1,2,3]
for i in testI[var seq[int], var int](lst):
  i += 1

在 D 编程语言中有这样的 'auto ref' 参数，根据它们是否是左值来选择是引用参数还是值参数。

为什么这个问题这么难？我不想每次创建迭代器时都必须复制粘贴函数。

Answer 1

通常在 Nim 中你会发现两个迭代器：items 和 mitems，一个用于获取项而不修改它们，另一个允许修改。在尝试实施一些疯狂的事情之前，我会努力使用这些程序。

但有些时候你必须实施它，所以每当你发现自己在 Nim 中遇到可以用 Ctrl-C Ctrl-V 解决的“代码重复”问题时，你应该想想在“模板”中。例如

template myCycle =
  ## Long and tedious code here.
  for i in 0 ..< arr.len:
    yield arr[i]

iterator testI[T](arr: seq[T]): T =
  echo "Non-var type"
  myCycle

iterator testI[T](arr: var seq[T]): var T =
  echo "Var type"
  myCycle

var lst1 = @[1,2,3]
for i in testI(lst1):
  echo i

let lst2 = @[1,2,3]
for i in testI(lst2):
  echo i

编译时，Nim 会为您复制 myCycle 中的长代码，并将其粘贴到您的两个迭代器中。请注意，您不必将 arr 传递给模板，因为它不是调用而是 copy-paste.

没有什么比你的最后一段代码更能说明我的第一点了。这是等效的代码：

iterator testI[T](a: var openArray[T]): var T {.inline.} =
  var i = 0
  while i < len(a):
    yield a[i]
    inc(i)

var lst = @[1, 2, 3]
for i in testI(lst):
  i += 1

echo lst
# @[2, 3, 4]

这是在 mitems 中为 openArrays 定义的代码（已经通过 system 导入到您的代码中），因此上面可以重写为：

var lst = @[1, 2, 3]
for i in mitems(lst):
  i += 1

echo lst
# @[2, 3, 4]

迭代器的通用可变和不可变参数

Generic mutable and nonmutable parameters for iterator

parameters

mutability

nim-lang