XSLT 3.0 身份转换文档集合？

Question

I have one XSLT 3.0:

<xsl:stylesheet version="3.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:map="http://www.w3.org/2005/xpath-functions/map"
    xmlns:n1="urn:hl7-org:v3">
    <xsl:output indent="yes" method="xml" encoding="utf-8"/>
    
    <xsl:param name="icd10Map" as="map(xs:string, xs:string)"
        select="
        map {
        '1742': 'C502',
        '55090': 'K409',
        '8442': 'S8350',
        '7172': 'M2332',
        '36616': 'H251',
        '4550': 'K648'        
        }"/>
    <xsl:variable name="map-keys" select="map:keys($icd10Map)"/>
    <xsl:mode on-no-match="shallow-copy"/>
    <xsl:template match="n1:translation[@codeSystemName = 'ICD-9-CM']/@code">
        <xsl:attribute name="code">
            <xsl:value-of select="$icd10Map($map-keys[translate(normalize-space(current()), ' &#x9;&#xa;&#xD;.;', '') = .])"/>
        </xsl:attribute>
    </xsl:template>
        
</xsl:stylesheet>

One input XML:

<?xml-stylesheet type="text/xsl" href="./Content/xsl/CDA.xsl"?>
<ClinicalDocument xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="urn:hl7-org:v3 NIST_C32_schema/C32_CDA.xsd" xmlns="urn:hl7-org:v3" xmlns:sdtc="urn:hl7-org:sdtc">
  <realmCode code="US" />
  <typeId root="2.16.840.1.113883.1.3" extension="POCD_HD000040" />
  <templateId root="2.16.840.1.113883.10.20.22.1.1" />
************************************************************
  <id extension="TT988" root="2.16.840.1.113883.19.5.99999.1" />
  <code codeSystem="2.16.840.1.113883.6.1" codeSystemName="LOINC" code="11504-8" displayName="Surgical Operation Note" />
  <title>Operative Report</title>
****************************************************
 <component>
    <structuredBody>
      <component>
        <section>
***********************
          <entry>
            <act moodCode="EVN" classCode="ACT">
              <templateId root="2.16.840.1.113883.10.20.22.4.65" />
              <code code="10219-4" codeSystem="2.16.840.1.113883.6.1" codeSystemName="LOINC" displayName="Preoperative Diagnosis" />
              <entryRelationship typeCode="SUBJ">
                <observation classCode="OBS" moodCode="EVN">
                  <code code="282291009" displayName="Diagnosis" codeSystem="2.16.840.1.113883.6.96" codeSystemName="SNOMED CT" />
                  <statusCode code="completed" />
                  <!-- ICD-9 be transformed to ICD-10 -->
                  <value nullFlavor="OTH" type="CD">
                    <translation code="366.16" displayName="Nuclear sclerosis" codeSystem="2.16.840.1.113883.6.103" codeSystemName="ICD-9-CM" />
                  </value>
                </observation>
              </entryRelationship>
            </act>
          </entry>
        </section>
      </component>

    </structuredBody>
  </component>
</ClinicalDocument>

The transformation scenario in Oxygen with just one document is without issue:

*******************  
                          <value nullFlavor="OTH" type="CD">
                              <translation code="H251"
                                           displayName="Nuclear sclerosis"
                                           codeSystem="2.16.840.1.113883.6.103"
                                           codeSystemName="ICD-9-CM"/>
                           </value>
******************

However, XSLT 3.0 identity transform for collection seems working like this:

    <xsl:variable name="inFile" as="node()*" select="collection('hl7.xml')"/>
    <xsl:template match="/">
        <xsl:text>&#xA;&#xA;  ICD9 Target Transformation in the collection is: &#xA; </xsl:text>
        <xsl:for-each select="$inFile//n1:translation[@codeSystemName = 'ICD-9-CM']/@code">
            <xsl:value-of select="$icd10Map($map-keys[translate(normalize-space(current()), ' &#x9;&#xa;&#xD;.;', '') = .])" separator=" , "/>
        </xsl:for-each>
    </xsl:template>

Result:

  ICD9 Target Transformation in the collection is: 
    H251    
    H251    
    K648    
    K648    
    K409    
    K409    
    S8350    
    M2332    
    M2332    
    S8350

If I change the XSLT to:

    <xsl:mode on-no-match="shallow-copy"/>
    <xsl:variable name="inFile" as="node()*" select="collection('hl7.xml')"/>
    <xsl:template match="n1:translation[@codeSystemName = 'ICD-9-CM']/@code">
        <xsl:text>&#xA;&#xA;  ICD9 Target Transformation in the collection is: &#xA; </xsl:text>
        <xsl:for-each select="$inFile">
            <xsl:attribute name="code">
            <xsl:value-of select="$icd10Map($map-keys[translate(normalize-space(current()), ' &#x9;&#xa;&#xD;.;', '') = .])" separator=" , "/>
            </xsl:attribute>
        </xsl:for-each>
    </xsl:template>

It doesn’t appear any transform happen and is merely an extraction of the URI list in the catalog file hl7.xml.

I develop a Java application which can bulk validate documents against XSD, transform (without collection()) and finally write the documents into database. The logging is the desired result:

Engine Instantiation: com.fc.andante.sax.SAXValidateStreamTransformWrite

Schema Validation Status: files in:/ml/Andante/data/data are validated against schema file:/ml/Andante/data/operation-transform.xsd

User 'auditor' has validated files in:/ml/Andante/data/data on 2020-08-26T23:05:26.357431

*****************

Transaction Status: Authenticating database writer... 

Transaction Status: User audited as 'super' is transforming document set...

Transaction Status: Document data/data/cataract.xml is successfully transformed and written into database with uri '/xslt-transform/cataract.xml'

Transaction Status: Document data/data/breast-surgery.xml is successfully transformed and written into database with uri '/xslt-transform/breast-surgery.xml'

Transaction Status: Document data/data/hernia.xml is successfully transformed and written into database with uri '/xslt-transform/hernia.xml'

Transaction Status: Document data/data/colonoscopy.xml is successfully transformed and written into database with uri '/xslt-transform/colonoscopy.xml'

Transaction Status: Document data/data/knee.xml is successfully transformed and written into database with uri '/xslt-transform/knee.xml'

Die Transaktion wurde erfolgreich abgeschlossen 2020-08-26T23:05:28.341385700

任何人都可以帮助解决 XSLT 3.0 集合转换问题吗？

Answer 1

我会使用全局参数

<xsl:param name="inFiles" as="document-node()*" select="collection('hl7.xml')"/>

然后开始使用命名模板进行处理

<xsl:template name="xsl:initial-template">
  <xsl:for-each select="$inFiles">
    <xsl:result-document href="/xslt-transform/{tokenize(document-uri(), '/')[last()]}">
      <xsl:apply-templates/>
    </xsl:result-document>
  </xsl:for-each>
</xsl:template>

然后您可以 xsl:import 从问题中获取您的第一个 XSLT 示例，当然也可以对其进行编辑以插入我展示的代码。确保让 Saxon 从命名模板开始（-it Saxon 的命令行选项；在 oXygen 中不提供源文档）。

XSLT 3.0 身份转换文档集合？

XSLT 3.0 Identity transform document collection?

java

xslt

xslt-3.0