OpenGL Alpha 值在着色器中无效

Question

我有一个简单的着色器可以在我的 2d 游戏中制作扫描线，它工作正常，如下所示：

#ifdef GL_ES
    precision mediump float;
#endif

varying vec4 v_color;
varying vec2 v_texCoords;

uniform sampler2D u_texture;

void main() {
    vec2 p = vec2(floor(gl_FragCoord.x), floor(gl_FragCoord.y));
    if (mod(p.y, 6.0)==0.0)
        gl_FragColor = vec4(0.0,0.0,0.0, 0.1);
    else
        gl_FragColor = v_color * texture2D(u_texture, v_texCoords);
}

但是，如果我更改 vec4 中片段颜色的 alpha 值，它没有任何效果，扫描线在 0.1 时和在 1.0 时一样黑。我看到了一些关于此的其他问题，建议启用混合，但我尝试了但无济于事。

这是我启用了混合的渲染方法。

@Override
public void render(float delta) {
    Gdx.gl.glClearColor(0.0f, 0.0f, 0.0f, 0);
    Gdx.gl.glClear(GL20.GL_COLOR_BUFFER_BIT);
    Gdx.gl.glEnable(GL20.GL_BLEND);
    Gdx.gl.glBlendFunc(GL20.GL_SRC_ALPHA, GL20.GL_ONE_MINUS_SRC_ALPHA);
    // batch.enableBlending(); tried this too but no effect
    batch.setProjectionMatrix(cam.combined);
    batch.setShader(shaderProgram);
    batch.begin();
    rendup.renderAll(batch);//renders all sprites, tiles etc
    batch.setShader(null);
    batch.end();
}

Answer 1

这不是混合问题。问题是您的着色器只绘制半透明的黑色像素，或正在绘制的任何纹理区域的颜色。这些黑色像素只是与屏幕上已有的内容混合（在本例中为黑色透明色）。

我假设您在这里真正想要的是扫描线不是纯黑色。所以你应该在所有地方绘制纹理区域的颜色，只是在扫描线所在的地方稍微变暗。您不想修改着色器输出的 alpha，或者当您有重叠的精灵时，扫描线会在该区域显得更暗。

所以像这样更改着色器：

#ifdef GL_ES
    precision mediump float;
#endif

varying vec4 v_color;
varying vec2 v_texCoords;

uniform sampler2D u_texture;

const float DARK_LINE_BRIGHTNESS = 0.9;

void main() {
    vec4 color = v_color * texture2D(u_texture, v_texCoords);
    vec2 p = vec2(floor(gl_FragCoord.x), floor(gl_FragCoord.y));
    if (mod(p.y, 6.0)==0.0)
        gl_FragColor = vec4(color.rgb * DARK_LINE_BRIGHTNESS, color.a);
    else
        gl_FragColor = color;
}

但是，if/else 应该避免在片段着色器中使用，因为在大多数情况下它的性能要差得多。（例外情况是 if 语句对一行中的许多像素计算出相同的值，例如 if (u_someUniformBoolean)。）您可以这样重写它：

void main() {
    vec4 color = v_color * texture2D(u_texture, v_texCoords);
    vec2 p = vec2(floor(gl_FragCoord.x), floor(gl_FragCoord.y));
    gl_FragColor = (step(0.01, mod(p.y, 6.0)) * (1.0 - DARK_LINE_BRIGHTNESS) + DARK_LINE_BRIGHTNESS) * color;
}

OpenGL Alpha 值在着色器中无效

OpenGL Alpha values having no effect in shader

java

opengl-es

libgdx

fragment-shader