需要通过 VBScript 在特定文件夹中重命名多个文件

Question

我需要通过 VBScript 重命名特定文件夹中的多个文件

示例：

将名称更改为具有数字约定的特定名称，例如将 Part1.csv 更改为 31-AUG-20-1.csv 并将 Part2.csv 更改为 31-Aug-29-2.csv

此处 20 年 8 月 31 日将保持不变，但数字会增加。因此，在下面的代码中，我不想为每个文件提供新名称，即 31-Aug-20-1.csv 而应该更改为 31-Aug-20（增量编号）

 Dim fso, folder, file, folderName, dict
    
    'Path
    folderName = "C:\User\desktop\ATL\"
    
    'Future FileName
    Set dict = CreateObject("Scripting.Dictionary")
    dict.Add "Part1.csv", "ATL-31-Aug-20-1.csv"
    dict.Add "Part2.csv", "ATL-31-Aug-20-2.csv"
    dict.Add "Part3.csv", "ATL-31-Aug-20-3.csv"
    dict.Add "Part4.csv", "ATL-31-Aug-20-4.csv"
    dict.Add "Part5.csv", "ATL-31-Aug-20-5.csv"
    dict.Add "Part6.csv", "ATL-31-Aug-20-6.csv"
    
    ' Create filesystem object and the folder object
    Set fso = CreateObject("Scripting.FileSystemObject")  
    Set folder = fso.GetFolder(folderName)  
    
    ' Loop over all files in the folder until the searchFileName is found
    For Each file In folder.Files
        If dict.Exists(file.Name) Then file.Name = dict(file.Name)
    Next

Answer 1

此代码将使用递增编号重命名文件：

Dim iCounter
Dim folderName
Dim fso, folder, file

' Path
folderName = "C:\User\desktop\ATL\"

' Create filesystem object and the folder object
Set fso = CreateObject("Scripting.FileSystemObject")  
Set folder = fso.GetFolder(folderName)  

iCounter = 1
For Each file In folder.Files
    file.Name = "ATL-32-Aug-20-" & iCounter & ".csv"
    iCounter = iCounter + 1
Next

如果想保留原文件名(Part#.csv)中的数字，可以添加如下逻辑：

Const vbTextCompare = 1
Dim folderName
Dim fso, folder, file
Dim sNumber
Dim sPrefix

' Path and prefix
folderName = "C:\User\desktop\ATL\"
sPrefix = "ATL-32-Aug-20-"

' Create filesystem object and the folder object
Set fso = CreateObject("Scripting.FileSystemObject")  
Set folder = fso.GetFolder(folderName)  

For Each file In folder.Files
    ' Check for "Part" and ".csv" in file name
    If StrComp(Left(file.Name, 4), "Part", vbTextCompare) = 0 And StrComp(Right(file.Name, 4), ".csv", vbTextCompare) = 0 Then
        ' Extract number
        sNumber = Mid(file.Name, 5, Len(file.Name) - 8)
        ' Rename file
        file.Name = sPrefix & sNumber & ".csv"
    End If
Next

需要通过 VBScript 在特定文件夹中重命名多个文件

Need to rename multiple files via VBScript in a particular folder

vbscript

filenames

file-rename