我如何在 ReScript 中遍历数组？

Question

假设我想以 Js/Belt 标准库函数不支持的方式遍历数组。例如，也许我需要一次检查成对的元素。使用列表，这很容易以递归方式完成：

let rec findDouble = (list) => switch list {
| list{a, b, ..._} when a == b => a
| list{_, b, ...rest} => findDouble(list{b, ...rest})
| _ => 0
}
list{7, 9, 10, 10, 11, 13} |> findDouble |> Js.log  // 10

然而，ReScript 似乎温和地阻止了支持数组的列表（参见：笨拙的列表语法和缺少某些标准库函数的列表等价物，如 Belt.Map.fromArray），所以我不确定是否将数组转换为列表只是为了使用这种样式是惯用的 - 特别是如果函数生成一个列表，然后必须将其转换回数组。

当然我可以使用可变性以传统的命令式方式实现功能：

let findDouble = (arr) => {
  let idx = ref(1)
  let answer = ref(0)

  while (idx.contents < Js.Array.length(arr)) && (answer.contents == 0) {
    if arr[idx.contents] == arr[idx.contents - 1] {
      answer := arr[idx.contents]
    }
    idx := idx.contents + 1
  }
  answer.contents
}
[7, 9, 10, 10, 11, 13] |> findDouble |> Js.log  // 10

但这很丑陋，并且与 ReScript 的功能骨架背道而驰。

实现此功能的简洁、惯用的方法是什么？

Answer 1

您仍然可以使用递归，只是递增索引而不是使用列表的尾部：

let findDouble = arr => {
  let rec loop = idx =>
    if idx >= Array.length(arr) {
      0
    } else if arr[idx] == arr[idx - 1] {
      arr[idx]
    } else {
      loop(idx + 1)
    }

  loop(1)
}

我如何在 ReScript 中遍历数组？

How do I generically traverse an array in ReScript?

arrays

rescript