Google 工作表查询重复第一行 + 结果错误

Question

我创建了一个 google 表格，通过一个函数到 google 表格，我创建了一个 2° 选项卡以使用 QUERY 过滤结果 你可以在这里看到结果

https://docs.google.com/spreadsheets/d/1nseIV5ieqsifOKwWvx7crbcTxxMZ3RKpb1kNUsoMt44/edit?usp=sharing

在“Ricerca”选项卡中，您可以过滤“Risultati”选项卡中的行。您可以看到 QUERY

=QUERY(Revisioni!A3:AI; "select * where (F contains '"&F2&"') and (E contains '"&H2&"') and
((Month(N)+1 = "&B2&" and year(N) = "&D2&" and O=false) or 
(Month(P)+1 = "&B2&" and year(P) = "&D2&" and Q=false) or 
(Month(R)+1 = "&B2&" and year(R) = "&D2&" and S=false) or 
(Month(T)+1 = "&B2&" and year(T) = "&D2&" and U=false) or 
(Month(V)+1 = "&B2&" and year(V) = "&D2&" and W=false) or 
(Month(X)+1 = "&B2&" and year(X) = "&D2&" and Y=false) or 
(Month(Z)+1 = "&B2&" and year(Z) = "&D2&" and AA=false) or 
(Month(AB)+1 = "&B2&" and year(AB) = "&D2&" and AC=false) or 
(Month(AD)+1 = "&B2&" and year(AD) = "&D2&" and AE=false) or 
(Month(AF)+1 = "&B2&" and year(AF) = "&D2&" and AG=false))")

在 Ricerca!A5 单元格中。

如您所见，结果类似于

合并第1°行+第1°resut行

怎样才能得到正确的结果？

Answer 1

解释：

您应该添加一个 0 作为 QUERY 的最后一个参数。

根据 documentation:

headers - [ OPTIONAL ] - The number of header rows at the top of data. If omitted or set to -1, the value is guessed based on the content of data.

因此，它假设源数据中的第三行 (A3) 是 header，这就是为什么将其添加到输出中的原因QUERY.

---

解决方案：

=QUERY(Revisioni!A3:AI; "select * where (F contains '"&F2&"') and (E contains '"&H2&"') and
((Month(N)+1 = "&B2&" and year(N) = "&D2&" and O=false) or 
(Month(P)+1 = "&B2&" and year(P) = "&D2&" and Q=false) or 
(Month(R)+1 = "&B2&" and year(R) = "&D2&" and S=false) or 
(Month(T)+1 = "&B2&" and year(T) = "&D2&" and U=false) or 
(Month(V)+1 = "&B2&" and year(V) = "&D2&" and W=false) or 
(Month(X)+1 = "&B2&" and year(X) = "&D2&" and Y=false) or 
(Month(Z)+1 = "&B2&" and year(Z) = "&D2&" and AA=false) or 
(Month(AB)+1 = "&B2&" and year(AB) = "&D2&" and AC=false) or 
(Month(AD)+1 = "&B2&" and year(AD) = "&D2&" and AE=false) or 
(Month(AF)+1 = "&B2&" and year(AF) = "&D2&" and AG=false))";0)

参考文献：

• Query()