调用函数时 Fortran 无限循环

Question

为什么我会陷入无限循环？

PROGRAM tayls
  USE kertoma
  USE tforexp
  IMPLICIT NONE
  INTEGER :: n= 5
  INTEGER :: i
  REAL :: x
  WRITE(*,*) "f1(x)= (e**x-1)/x"
  DO i=1,10
    x= 0.01*i
    WRITE(*,*)x, (taylexp(x,n)-1)/x
  END DO
END PROGRAM tayls

和

MODULE tforexp
  USE kertoma
  IMPLICIT NONE
    CONTAINS
      FUNCTION taylexp(x,ord)
        REAL :: taylexp, x, sum
        INTEGER :: ord, i
        sum= 1.0
        DO i=1,ord
          sum= sum+ x**i/fact(i)
        END DO
        taylexp= sum
      END FUNCTION taylexp
END MODULE tforexp

和

MODULE kertoma
  IMPLICIT NONE
CONTAINS
  FUNCTION fact(n)
    INTEGER :: fact,n,y=1
    DO WHILE (n>1)
      y= y*n
      n= n-1
    END DO
    fact = y
  END FUNCTION fact
END MODULE kertoma

无限循环在第一次打印后立即开始 "f1(x)=..."。所以我认为它在第一次调用 taylexp 函数时会进入无限循环，但我不明白为什么。我认为它与使用 public 变量的 fortran 有关，但我不知道如何始终如一地避免这种情况。首先，我尝试在不定义 x 的情况下调用该函数，仅使用“0.01*i”，我认为问题可能在于该函数对虚拟索引使用了相同的名称，但显然它没有解决问题。

Answer 1

问题出在 then 函数内部 fact(n):

n= n-1

更改参数，因此更改 taylexp 中的循环计数器 i。在您的代码中 i 永远不会超过 2。我很惊讶编译器没有发出警告（我的也没有），因为在这种情况下可能会发生任何事情。

最好指定 intent 伪参数以避免将来出现此类问题：

  FUNCTION fact(n)
    integer,intent(in)  :: n
    INTEGER :: fact,nn,y

    y=1 ! Avoid the implicit save and assign variables separately
    nn=n
    DO WHILE (nn>1)
      y= y*nn
      nn= nn-1
    END DO
    fact = y
  END FUNCTION fact

Answer 2

使用 gfortran 可以捕获此错误 -fcheck=all 选项：

$ gfortran -fcheck=all 1.f90 
$ ./a.out
 f1(x)= (e**x-1)/x
At line 22 of file 1.f90
Fortran runtime error: Loop variable has been modified

调用函数时 Fortran 无限循环

Fortran infinite loop when calling a function

fortran

infinite-loop

fortran95