Escape XML 不考虑使用 XSLT 的名称空间并被忽略（使用 Mule XSLT 组件）

Question

我正在尝试转义 xml 的一部分并使用我通过堆栈流获得的 XSLT 脚本我能够转义特定节点但是名称 space 被忽略了。示例如下

<root>
   <parent>test</parent>
   <parentdtl>
   <child xmlns="http://test.com">
       <element1>1</element1>
   </child>   
   </parentdtl>
   <outer>T</outer>
</root>

使用 XSLT 代码

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
xmlns="http://test.com">
    <xsl:template match="*">
        <xsl:text disable-output-escaping="no">&lt;</xsl:text>
        <xsl:value-of select="name()"  />
        <xsl:apply-templates select="@*"  />
        <xsl:text disable-output-escaping="no">&gt;</xsl:text>
        <xsl:apply-templates select="node()" />
        <xsl:text disable-output-escaping="no">&lt;/</xsl:text>
        <xsl:value-of select="name()" />
        <xsl:text disable-output-escaping="no">&gt;</xsl:text>
    </xsl:template>
   <xsl:template match="@*" >
    <xsl:text disable-output-escaping="no">&#32;</xsl:text>
    <xsl:value-of select="name()" disable-output-escaping="no"/>
    <xsl:text disable-output-escaping="yes">=&amp;quot;</xsl:text>
    <xsl:value-of select="." disable-output-escaping="no"/>
    <xsl:text disable-output-escaping="yes">&amp;quot;</xsl:text>
</xsl:template>
<xsl:template match="root|parent|parentdtl|outer">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

但是接收到的输出没有名称 space，如下所示

<?xml version="1.0" encoding="UTF-8"?><root>
   <parent>test</parent>
   <parentdtl>
   &lt;child&gt;
       &lt;element1&gt;1&lt;/element1&gt;
   &lt;/child&gt;   
   </parentdtl>
   <outer>T</outer>
</root>

如果我需要添加任何逻辑来包含名称，请告诉我space

Answer 1

借助 XSLT 3 支持，您可以使用 serialize 函数：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

   <xsl:template match="*">
       <xsl:value-of select="serialize(.)"/>
   </xsl:template>

   <xsl:template match="root|parent|parentdtl|outer">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template> 
    
</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/jxN9PRK/1

对于 serialize 的旧版本（非 XPath 3.1），您可能需要

   <xsl:template match="*">
       <xsl:variable name="ser-params" as="element()">
          <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization">
             <output:omit-xml-declaration value="yes"/>
          </output:serialization-parameters>
       </xsl:variable>
       <xsl:value-of select="serialize(., $ser-params)"/>
   </xsl:template>

避免 XML 声明。

Escape XML 不考虑使用 XSLT 的名称空间并被忽略（使用 Mule XSLT 组件）

Escape XML not considering the namespace using XSLT and getting ignored (using Mule XSLT component)

xml

xslt

escaping