Moose 从单个参数构造对象

Question

我已经接触 Moose 大约七个月了，而 Perl 的时间只稍微长了一点，但无法弄清楚如何通过为每个属性提供一个参数来在 class 中构造多个属性，而不是他们的整个哈希引用。我广泛地搜索了文档和网络，但我要么在寻找错误的词，要么遗漏了一些东西。

我对设计进行了调整，使其更加通用。使用以下基本设置：

package First;
use Moose;
use Second::Type1;
use Second::Type2;
has 'type1' => (
  is => 'rw',
  isa => 'Second::Type1',
  default => sub {Second::Type1->new(name => 'random')}
);

has 'type2' => (
  is => 'rw',
  isa => 'Second::Type2',
  default => sub {Second::Type2->new(name => 'random')}
);

package Second::Type1;
use Moose;
use This;
has 'name' => (
  is => 'rw',
  isa => 'Str',
  required => 1,
);
has 'this' => (
  is => 'rw',
  isa => 'This',
  default => sub {This->new()}
);
# package has more attributes, but you get the idea
__PACKAGE__->meta->make_immutable();
no Moose;
1;

package Second::Type2;
use Moose;
use That;
has 'name' => (
  is => 'rw',
  isa => 'Str',
  required => 1,
);
has 'that' => (
  is => 'rw',
  isa => 'That',
  default => sub {That->new()}
);
# package has more attributes, but you get the idea
__PACKAGE__->meta->make_immutable();
no Moose;
1;

我希望能够构建一个 First，方法是：

use First;
my $first = First->new(type1 => 'foo', type2 => 'bar');

其中 'foo' 等于 Second::Type1 的 'name' 属性的值，'bar' 等于 Second::Type2 的 'name' 的值属性。

现在关于我自己的解决方案，我已经（成功地）制作了一个 Moose::Role，它只包含一个 'around BUILDARGS' sub，然后使用一个 Factory class（其中的内容IMO):

package Role::SingleBuildargs;

use Moose::Role;
use Factory::Second;
requires 'get_supported_args';

around BUILDARGS => sub {
my ($class, $self, %args) = @_;
my @supported_args = $self->get_supported_args;
my $factory = Factory::Second->new();
    my @errors = ();
    foreach my $arg (sort {$a cmp $b} keys %args) {
        if (grep {$_ eq $arg} @supported_args) {
            my $val = $args{$arg};
            if (!ref $val) {    # passed scalar init_arg
                print "$self (BUILDARGS): passed scalar\n";
                print "Building a Second with type '$arg' and name '$val'\n";
                $args{$arg} = $factory->create(type => $arg, name => $val)
            } elsif (ref $val eq 'HASH') {  # passed hashref init_arg
                print "$self (BUILDARGS): passed hashref:\n";
                my %init_args = %$val;
                delete $init_args{name} unless $init_args{name};
                $init_args{type} = $arg;
                $args{$arg} = $factory->create(%init_args);
            } else {    # passed another ref entirely
                print "$self (BUILDARGS): cannot handle reference of type: ", ref $val, "\n";
                die;
            }
        } else {
            push @errors, "$self - Unsupported attribute: '$arg'";
        }
    }
    if (@errors) {
        print join("\n", @errors), "\n";
        die;
    }
    return $self->$class(%args);
    };

no Moose;
1;

然后我在 First class 和 First 等其他 class 中使用该角色。

我也试过通过以下方式强制：

package Role::Second::TypeConstraints;
use Moose::Util::TypeConstraints

subtype 'SecondType1', as 'Second::Type1';
subtype 'SecondType2', as 'Second::Type2';
coerce 'SecondType1', from 'Str', via {Second::Type1->new(name => $_};
coerce 'SecondType2', from 'Str', via {Second::Type2->new(name => $_};

no Moose::Util::TypeConstraints;
1;

并修改了第一个包（仅列出更改）：

use Role::Second::TypeConstraints;
has 'type1' => (
   isa => 'SecondType1',
   coerce => 1,
);
has 'type2' => (
   isa => 'SecondType2',
   coerce => 1,
);

但是，那没有用。如果有人能解释为什么，那就太好了。

至于实际问题：在您的 classes 中获得这种行为的最佳方法是什么？真的没有比修改 BUILDARGS 更好的方法了吗，还是我错过了什么（大概 Moose::Util::TypeConstraints）？ TMTOWTDI 等等，但我的似乎根本没有效率。

编辑：为保持一致性而编辑（混淆了通用 class 名称）

Answer 1

你绝对可以用类型和强制转换来做到这一点。尝试使用 MooseX::Types 而不是内置的。

这是一个小例子，部分摘自 MooseX::Types 文档。

package Foo;
use Moose;
use MooseX::Types -declare => [qw(MyDateTime)];
use MooseX::Types::Moose 'Int';
use DateTime;

class_type MyDateTime, { class => 'DateTime' };
coerce MyDateTime, from Int, via { DateTime->from_epoch( epoch => $_ ) };

has date => (
    is      => 'ro',
    isa     => MyDateTime,
    default => sub {time},
    coerce  => 1,
);

package main;

my $foo = Foo->new;
say 'without args: ', $foo->date;

my $bar = Foo->new( date => time - 24 * 3600 );
say 'with args:    ', $bar->date;

这将打印如下内容：

without args: 2015-06-26T13:35:38
with args:    2015-06-25T13:35:38

它看起来很像你拥有的，只是使用了较新的类型。试一试。

Answer 2

您可以完全按照您描述的方式使用强制转换

添加
```
use Moose::Util::TypeConstraints;
```
到First、Second::Type1和Second::Type2

向Second::Type1添加强制操作

coerce 'Second::Type1'
    => from 'Str'
        => via { Second::Type1->new( name => $_ ) };

和Second::Type2

coerce 'Second::Type2'
    => from 'Str'
        => via { Second::Type2->new( name => $_ ) };

为 First

的 type1 和 type2 属性启用强制转换

has 'type1' => (
  is      => 'rw',
  isa     => 'Second::Type1',
  default => sub { Second::Type1->new },
  coerce  => 1,
);

has 'type2' => (
  is      => 'rw',
  isa     => 'Second::Type2',
  default => sub { Second::Type2->new },
  coerce  => 1,
);

然后你就可以按照你说的那样创建一个First对象，用

my $first = First->new(type1 => 'foo', type2 => 'bar');

Moose 从单个参数构造对象

Moose construct objects from single arguments

perl

moose

type-constraints