带有方案的纯功能堆栈实现

Question

我想在方案中实现功能堆栈。这是我的尝试：

(define make-stack
  (letrec ((do-op
            (lambda (stack op . val)
              (cond ((eq? op 'push)
                     (lambda (op . v)
                       (do-op (cons (car val) stack) op v)))
                    ((eq? op 'pop)
                     (lambda (op . v)
                       (do-op (cdr stack) op v)))
                    ((eq? op 'print)
                     (begin (display stack)
                            (newline)
                            (lambda (op . v)
                              (do-op stack op v))))))))
    (lambda (op . val)
      (do-op '() op val))))

堆栈可以像本例中那样使用：

(define s make-stack)
((((((s 'push 1) 'push 2) 'push 3) 'print) 'pop) 'print)

这个例子的输出是：

((3) (2) (1))
((2) (1))

不完全是我想要的，但还不错。想在这里请教有经验的schemer们有没有办法让stack表现的更自然一些，比如像这样：

(define s make-stack)
(s 'push 1)
(s 'push 2)
(s 'pop)
...

同时保持其功能（因此没有可变性，没有 set!）。

我首先想到的是继续返回一个不带参数的函数，但每个 lambda (op . v) 更改为：

(lambda ()
  (lambda (op . v)
    ...

但这不起作用，因为我们仍然需要捕获返回的函数：

> (define s make-stack)
> ((s) 'push 1)
#<procedure>

Answer 1

你们的目标是矛盾的。如果 s 是一个堆栈，并且您的操作纯粹是函数式的，那么 (s 'push 1) 每次调用时都必须 return 同样的事情。要捕捉变化的概念，您必须每次都使用不同的 s。这就是您的函数堆栈的工作方式：它返回给您一个新的堆栈，并且您必须用它组合函数调用。

Answer 2

正如 Amalloy 所建议的那样，实用风格的原则与您的目标形成鲜明对比。做一些类似的事情并非不可能，但是-

(define (run-stack s prgm)
  (foldl (lambda (step s) (apply s step))
         s
         prgm))

(run-stack
  make-stack
 '((push 1)
   (push 2)
   (push 3)
   (print)
   (pop)
   (print)))

为了测试这一点，我将 make-stack 实现为 -

(define (dispatch-stack s)
  (lambda payload
    (match payload
      ((list 'pop)
       (dispatch-stack (cdr s)))
      ((list 'push v)
       (dispatch-stack (cons v s)))
      ((list 'print)
       (println (reverse s))
       (dispatch-stack s))
      (_ (error "invalid stack operation" payload)))))

(define make-stack
  (dispatch-stack null))

输出-

'(1 2 3)
'(1 2)

我认为您希望看到的另一件事是 Make a language in one hour: stacker。这将帮助您了解像 Racket 这样的语言与您以前可能使用过的其他语言有何根本不同。

带有方案的纯功能堆栈实现

Purely functional stack implementation with scheme

scheme

stack

functional-programming

purely-functional