Terraform

Question

我在迭代由 templatefile 函数解释的模板中的对象列表时遇到问题。

我有以下变量：

variable "destinations" {
  description = "A list of EML Channel Destinations."

  type = list(object({
    id  = string
    url = string
  }))
}

这将作为 destinations 传递给 templatefile 函数。模板相关的片段是这样的：

Destinations:
  %{ for dest in destinations ~}
  - Id: ${dest.id}
    Settings:
      URL: ${dest.url}
  %{ endfor }

规划 Terraform 时会出现以下错误：

Error: "template_body" contains an invalid YAML: yaml: line 26: did not find expected key

我尝试将模板代码切换为以下内容：

Destinations:
  %{ for id, url in destinations ~}
  - Id: ${id}
    Settings:
      URL: ${url}
  %{ endfor }

这给出了不同的错误：

Call to function "templatefile" failed:
../../local-tfmodules/eml/templates/eml.yaml.tmpl:25,20-23: Invalid template
interpolation value; Cannot include the given value in a string template:
string required., and 2 other diagnostic(s).

[!] something went wrong when creating the environment TF plan

我的印象是我在此处对数据类型的迭代在某种程度上是不正确的，但我无法理解如何并且我根本找不到任何关于此的文档。

这是我如何调用此模块的简化示例：

module "eml" {
  source = "../../local-tfmodules/eml"

  name = "my_eml"

  destinations = [
    {
      id  = "6"
      url = "https://example.com"
    },
    {
      id  = "7"
      url = "https://example.net"
    }
  ]
<cut>
}

Answer 1

您不能将 var.destinations 作为地图列表传递给模板。它必须是 list/set 个字符串。

但您可以执行以下操作：

templatefile("eml.yaml.tmpl", 
          { 
            ids =  [for v in var.destinations: v.id]
            urls =  [for v in var.destinations: v.url] 
          }
    )

其中 eml.yaml.tmpl 是

Destinations:
  %{ for id, url in zipmap(ids, urls)  ~}
  - Id: ${id}
    Settings:
      URL: ${url}
  %{ endfor ~}

Answer 2

我刚刚发现（在制作了一个小型 Terraform 模块以仅测试 templatefile 输出之后）原始配置确实有效（至少在 TF v0.12.29 中）。

给出的错误有点转移注意力 - 问题与模板内的缩进有关，例如而不是：

Destinations:
  %{ for destination in destinations  ~}
  - Id: ${destination.id}
    Settings:
      URL: ${destination.url}
  %{ endfor ~}

应该是：

Destinations:
  %{~ for destination in destinations  ~}
  - Id: ${destination.id}
    Settings:
      URL: ${destination.url}
  %{~ endfor ~}

请注意 Terraform 指令开头的额外波浪号 (~)。这使得 Yaml 对齐正常工作（你得到一些错误缩进的行和一些空行）。在此之后，我问题中的原始代码按我的预期工作并生成有效的 yaml。

Answer 3

由于您的目标是生成 YAML 结果，我建议遵循 the templatefile documentation about generating JSON or YAML from a template 中的建议。

使用 the yamlencode function 将保证结果始终是有效的 YAML，您不必担心正确定位换行符或 quoting/escaping 可能包含特殊字符的字符串。

这样写你的 templatefile 电话：

templatefile("${path.module}/templates/eml.yaml.tmpl", {
  destinations = var.destinations
})

然后，在eml.yaml.tmpl中，使整个模板成为调用yamlencode的结果，像这样：

${yamlencode({
  Destinations = [
    for dest in destinations : {
      Id = dest.id
      Settings = {
        URL = dest.url
      }
    }
  ]
})

请注意 yamlencode 的参数是 Terraform expression syntax 而不是 YAML 语法，因为在这种情况下，Terraform 负责进行 YAML 编码，您需要做的就是提供合适的值对于要编码的 Terraform，遵循 yamldecode 文档中给出的从 Terraform 类型到 YAML 类型的映射。

Terraform - 迭代模板中的对象列表

Terraform - Iterate over a List of Objects in a Template

function

terraform0.12+