在 XSLT 中创建动态数组

Question

我有一个要求，我必须将每个 <troubleticketalarm> 详细信息连接到每个警报的一个字符串中，然后将其映射到我的 xslt 中的描述字段。说明在我的 xslt 中属于数组类型。

这是我的xml,

<ticketDetails>
    <alarms> 
        <troubleticketalarm> 
            <alarmId>3117</alarmId>
            <alarmName>OSS</alarmName> 
            <amo>amo</amo> 
            <alarmedEquipment>alarmedEquipment</alarmedEquipment> 
            <severity>1</severity> 
            <specificProblem>specificProblem</specificProblem>
            <probableCause>probableCause</probableCause>
            <activationDate>2015-03-17T17:33:04</activationDate>
            <associationDate>2015-03-17T17:33:04</associationDate>
            <clearDate>2015-03-17T17:33:04</clearDate>
        </troubleticketalarm> 
        <troubleticketalarm> 
            <alarmId>3118</alarmId> 
            <alarmName>OSS123</alarmName>
            <activationDate>2015-03-17T17:33:0405:30</activationDate>
            <asociationDate>2015-03-17T17:33:0405:30</asociationDate>
            <clearDate></clearDate>
        </troubleticketalarm>
        <troubleticketalarm> 
            <alarmId>3119</alarmId> 
            <alarmName>OSS124</alarmName>
            <amo>amo</amo> 
            <alarmedEquipment>alarmedEquipment</alarmedEquipment> 
            <severity>1</severity> 
            <activationDate>2015-03-17T17:33:0405:30</activationDate>
            <asociationDate>2015-03-17T17:33:0405:30</asociationDate>
            <clearDate></clearDate>
        </troubleticketalarm>
    </alarms>
</ticketDetails>

这是xslt的一部分：

<ns:Description type="Array">
     <ns:Description type="String" mandatory="" readonly=""></ns:Description>
</ns:Description>

我想要的是连接由“|”分隔的值并将

的每个连接值映射到 ns:Description

连接的字符串看起来像这样

3117|OSS|amo|alarmedEquipment|1|specificProblem|probableCause|2015-03-17T17:33:04+05:30|2015-03-17T17:33:04+05:30|2015-03-17T17:33:04+05:30

3118|OSS123|||||||2015-03-17T17:33:04+05:30|

3119|OSS124|amo|alarmedEquipment|1|||2015-03-17T17:33:04+05:30|2015-03-17T17:33:04+05:30|

应将这 3 个字符串添加到 Description[0]、Description[1]、Description[1]。 xml 中可能有多个 <troubleticketalarm> 标签，因此 xslt 描述应该是动态的。

我该如何实现？如果问题不清楚，请告诉我。

编辑

我的 XSLT 文件看起来像

<xsl:stylesheet version='2.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
    <xsl:output method="xml" encoding="UTF-8" indent="yes" />
    <xsl:template match='/'>
        <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:ns="http://schemas.hp.com/SM/7" xmlns:com="http://schemas.hp.com/SM/7/Common" xmlns:xm="http://www.w3.org/2005/05/xmlmime">
           <soapenv:Header/>
           <soapenv:Body>
              <ns:CloseIncidentRequest attachmentInfo="" attachmentData="" ignoreEmptyElements="true" updateconstraint="-1">
                 <ns:model query="">
                    <ns:keys query="" updatecounter="1">
                       <ns:IncidentID type="String" mandatory="" readonly=""></ns:IncidentID>
                    </ns:keys>
                    <ns:instance query="" uniquequery="" recordid="" updatecounter="1">
                        <ns:IncidentID type="String" mandatory="" readonly=""></ns:IncidentID>
                        <ns:Description type="Array">
                                <ns:Description type="String" mandatory="" readonly=""></ns:Description>
                        </ns:Description>
                        ......
                        ......
                    </ns:instance>
                </ns:model>
              </ns:CloseIncidentRequest>
            </soapenv:Body>
        </soapenv:Envelope>
    </xsl:template>
</xsl:stylesheet>

Answer 1

据我了解，您正在尝试连接 <troubleticketalarm> 下节点的值并将其映射到您的 xslt 文件中的字段之一 (<ns:Description>)。

也许您可以尝试使用 for-each 循环并在循环内连接值：

<ns:Description type="Array">
 <xsl:for-each select="/ticketDetails/alarms/troubleticketalarm">
     <ns:Description type="String" mandatory="" readonly="">
        <xsl:value-of select="concat(alarmId,'|',alarmName,'|',amo,'|',alarmedEquipment,'|',severity,'|',specificProblem,
        '|',probableCause,'|',associationDate,'|',activationDate,'|',clearDate)" />
     </ns:Description>
 </xsl:for-each>
</ns:Description>

Answer 2

如果您不知道子元素的数量和名称，但想使用包含大多数子元素的 troubleticketalarm 作为列表的定义，那么

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

    <xsl:output method="text" />
    <xsl:strip-space elements="*"/>

    <xsl:variable name="alarms" select="//troubleticketalarm"/>
    <xsl:variable name="max" select="max($alarms/count(*))"/>
    <xsl:variable name="col-names" select="$alarms[count(*) eq $max]/*/local-name()"/>

    <xsl:key name="k1" match="troubleticketalarm/*" use="local-name()"/>

    <xsl:template match="troubleticketalarm">
        <xsl:value-of select="for $name in $col-names return (if (key('k1', $name, current())) then key('k1', $name, current()) else '')" separator="|"/>
        <xsl:text>&#10;</xsl:text>
    </xsl:template>

</xsl:transform>

可能会有帮助。它在 http://xsltransform.net/gWmuiJY 在线并输出

3117|OSS|amo|alarmedEquipment|1|specificProblem|probableCause|2015-03-17T17:33:04|2015-03-17T17:33:04|2015-03-17T17:33:04
3118|OSS123||||||2015-03-17T17:33:0405:30||
3119|OSS124|amo|alarmedEquipment|1|||2015-03-17T17:33:0405:30||

在 XSLT 中创建动态数组

Creating dynamic array in XSLT

xml

arrays

xslt

xslt-2.0