字符串函数子句匹配

Question

我运行在为旧的 Advent of Code 任务编写一些简单的 erlang 代码时遇到了问题。

下面的程序应该读取行，按出现次数对字符串中的字符进行分组，然后计算重复三个字符的行数。


count_occurrences([], Map) -> Map;
count_occurrences([H | T], Map) ->
    count_occurrences(T, maps:put(H, maps:get(H, Map, 0) + 1, Map)).

count(Line, Count) ->
    Map = count_occurrences(Line, #{}),
    case lists:member(3, maps:values(Map)) of
        true -> Count + 1;
        false -> Count
    end.

run() ->
    {ok, Binary} = file:read_file("data.txt"),
    Lines = binary:split(Binary, <<"\n">>, [global]),
    Result = lists:foldl(fun count/2, 0, Lines),
    Result.

但是，我收到此错误消息：

10> c(day2).   
{ok,day2}
11> day2:run().
** exception error: no function clause matching day2:count_occurrences(<<"bpacnmelhhzpygfsjoxtvkwuor">>,#{}) (day2.erl, line 5)
     in function  day2:count/2 (day2.erl, line 10)
     in call from lists:foldl/3 (lists.erl, line 1263)

我不明白为什么 <<"bpacnmelhhzpygfsjoxtvkwuor">>,#{} 不匹配第二个“count_occurrences”函数子句 - 字符串与列表相同，对吗？为什么不匹配 [H | T]?

Answer 1

你得到这个错误，因为函数 count_occurrences/2 期望第一个参数 list - [<<"bpacnmelhhzpygfsjoxtvkwuor">>] 或 "bpacnmelhhzpygfsjoxtvkwuor" 但被放入 binary - <<"bpacnmelhhzpygfsjoxtvkwuor">> .仔细检查第 10 行模块 day2.erl 的函数 count/2 中的输入数据 Line：

1> is_list([]).
true
2> is_list("").
true
3> is_list(<<"">>).
false
4> is_list(binary_to_list(<<"">>)).
true

Answer 2

看看这个例子：

-module(a).
-compile(export_all).

go([_H|_T], _X) ->
    "First arg was a list";
go("a", _X) ->
    "First arg was a string";
go(<<"a">>, _X) -> 
    "First arg was a binary".

在shell中：

5> a:go(<<"a">>, #{a=>1, b=>2}).
"First arg was a binary"

和：

6> a:go("a", #{a=>1, b=>2}).    
"First arg was a list"

a string is the same as a list, right?

是的，双引号字符串是创建整数列表的快捷方式，其中列表中的整数是字符的 ascii 代码。因此，上面的第二个函数子句永远不会匹配：

a.erl:6: Warning: this clause cannot match because a previous clause at line 4 always matches

但是....二进制，例如 <<"abc">> 不是字符串，因此二进制不是创建整数列表的快捷方式。

8> "a" =:= [97].
true

好的，你知道的。但是，现在：

9> "a" =:= <<"a">>.
false

10> <<"a">> =:= <<97>>.
true

11> "a" =:= <<97>>.
false

最后：

13> <<"abc">> =:= <<97, 98, 99>>.
true

最后一个示例表明，在二进制文件中指定双引号字符串只是在二进制文件中指定逗号分隔的整数列表的快捷方式——但是在二进制文件中指定双引号字符串不会以某种方式转换二进制文件到列表。

Answer 3

请注意，您也可以使用略有不同的语法遍历二进制文件：

count_occurrences(<<>>, Map) -> Map;
count_occurrences(<<H, T/binary>>, Map) ->
    count_occurrences(T, maps:put(H, maps:get(H, Map, 0) + 1, Map)).

默认情况下，H 被假定为一个字节，但您可以添加修饰符来指定要 select 的位数等等。见 documentation for the Bit Syntax.

字符串函数子句匹配

String function clause matching

erlang