qt qml checkbox：当用户点击但未被q_property绑定选中时如何执行代码

Question

我在 qt 中有一个复选框，我想通过绑定到代码的 q_property 成为 checked，但也可以由用户来实现。当用户单击复选框时，我想运行一些代码。问题是当通过代码和用户输入选中复选框时，似乎会调用 onChecked 回调。此代码将涉及稍后通过代码 checked 复选框，这将触发 onChecked 回调。 Qt 提供的回调如何最好地处理这种情况？

如果以上内容没有意义，请了解更多背景信息：此复选框通过网络连接控制机器人的一项功能，但它还应显示该功能的状态，因为它可以自动启用或从以前的session。 q_property robotStatus.missionLooping 由定期状态更新设置。当用户选中该框时，它应该触发网络调用以启用该功能，然后状态更新将在片刻之后发生，这将看到该功能已启用并选中该框（即使它已经被选中）。

AppCheckBox.qml:

import QtQuick 2.15
import QtQuick.Controls 2.15

CheckBox
{
    id: root

    indicator: Rectangle
    {
        implicitWidth: utilities.dp(40)
        implicitHeight: utilities.dp(40)
        x: root.leftPadding
        y: parent.height / 2 - height / 2

        Rectangle
        {
            width: utilities.dp(20)
            height: utilities.dp(20)
            x: utilities.dp(10)
            y: utilities.dp(10)
            radius: utilities.dp(3)
            color: theme.green
            visible: root.checked
        }
    }

    contentItem: Text
    {
        text: root.text
        font: root.font
        opacity: enabled ? 1.0 : 0.3
        color: theme.white
        verticalAlignment: Text.AlignVCenter
        leftPadding: root.indicator.width + root.spacing
        //font.pointSize: constants.coordinatesTextPointSize + 1
        minimumPointSize: constants.minimalCoordinatesTextPointSize
    }
}

ui.qml:

    AppCheckBox
    {
        id: missionLoopingCheckbox
        enabled: isConnected
        checked: robotStatus.missionLooping
        text: qsTr("Mission Looping")
    }

Answer 1

您可以实现 onToggled 信号处理程序。 toggled 当用户通过触摸、鼠标或键盘以交互方式切换可检查按钮时，会发出信号。

下面我假设 robotStatus.missionLooping 是只读的属性。您需要 Q_INVOKABLE 方法或槽函数来调用例如robotApi.loopMission(bool) 通过网络调用机器人并在循环 starts/stops.

时导致 robotStatus.missionLooping 属性变为 true/false

AppCheckBox
{
    id: missionLoopingCheckbox
    enabled: isConnected
    checked: robotStatus.missionLooping
    text: qsTr("Mission Looping")
    onToggled: {
        robotApi.loopMission(missionLoopingCheckbox.checked)
    }
}

qt qml checkbox：当用户点击但未被q_property绑定选中时如何执行代码

qt qml checkbox: How to execute code when clicked by user but not checked by q_property binding

qt

qtquickcontrols