寻找一种更简洁的嵌套循环方式

Question

正在寻找 cleaner/more-readable 在 Terraform 中实现嵌套循环的方法。我会举例说明。

假设我们有如下所示的角色变量：

variable "roles" {
  type    = "list"
  default = [
    {
      name    = "LOADER"
      schemas = {
        RAW = ["USAGE", "ALL"]
        SRC = ["ALL"]
      }
    },
    {
      name    = "USER"
      schemas = {
        RAW = ["DELETE", "OBJECT"]
        SRC = ["USE"]
      }
    }
  ]
}

据此，我想得到一个看起来像这样的字典列表：

output = [
  {
    "privilege" = "USAGE"
    "role" = "LOADER"
    "schema" = "RAW"
  },
  {
    "privilege" = "ALL"
    "role" = "LOADER"
    "schema" = "RAW"
  },
  {
    "privilege" = "ALL"
    "role" = "LOADER"
    "schema" = "SRC"
  },
  {
    "privilege" = "DELETE"
    "role" = "USER"
    "schema" = "RAW"
  },
  {
    "privilege" = "OBJECT"
    "role" = "USER"
    "schema" = "RAW"
  },
  {
    "privilege" = "USE"
    "role" = "USER"
    "schema" = "SRC"
  },
]

到目前为止我已经尝试过的方法（似乎有效，但我正在寻找更 concise/readable 的方法来做到这一点）：

locals {
  # FlatMapping to a list of dictionaries. Each dict in the form of {schema=<schema>, role=<role>, privilege=<privilege>}
  key_val       = [for role in var.roles : [for schema, privilege in role["schemas"]: {
    role      = role["name"]
    schema    = schema
    privilege = privilege
  }]]
  other_key_val = [for dict in flatten(local.key_val): [for priv in dict["privilege"]: {
    role      = dict["role"]
    schema    = dict["schema"]
    privilege = priv
  }]]
}

output "output" {
  value = flatten(local.other_key_val)
}

我的主要 objective 是拥有可读的代码，让其他人更好地理解。鉴于我是第一次在 Terraform 中使用循环，我无法判断我的实现是否被认为是可读的。

Answer 1

也许这是获得相同结果的更简单的方法：

locals {
  roles = [
      {
        name    = "LOADER"
        schemas = {
          RAW = ["USAGE", "ALL"]
          SRC = ["ALL"]
        }
      },
      {
        name    = "USER"
        schemas = {
          RAW = ["DELETE", "OBJECT"]
          SRC = ["USE"]
        }
      }
  ]

  out = flatten([
    for item in local.roles: [
      for schema, privileges in item.schemas: [
        for privilege in privileges: {
          role = item.name
          privilege = privilege
          schema = schema
        }
      ]
    ]
  ])
}

寻找一种更简洁的嵌套循环方式

Looking for a more concise way of doing a nested loop

terraform

hcl