LCD 在模拟环境中不工作

Question

我正在使用 Tinkercad，由于这是我第一次对 LCD 编程，所以我只是复制了连接引脚并使其工作的程序。

问题是它只是亮了，没有显示任何东西，我尝试了连接和断开 R/W 引脚，但这也不起作用，什么都不会显示。

我错过了什么？代码其他功能正常。

电路图：

这是代码：

#include <LiquidCrystal.h>

const int pin = 0; // analog pin
float celsius = 0, farhenheit =0; // temperature variables
float millivolts; //Millivolts from the sensor
int sensor;

const int G_LED = 13;
const int Y_LED = 12;
LiquidCrystal lcd(10, 9, 5, 4, 3, 2); // Building the LCD


void setup() {
  lcd.begin(16,2);              
  lcd.clear();                  
  lcd.setCursor(0,0);           
  lcd.print("C=");           // "C=", "F=" and "mV" should be printed
  lcd.setCursor(0, 1);       // on the LCD in a column  
  lcd.print("F=");           
  lcd.setCursor(0, 2);            
  lcd.print("mV=");
  
  pinMode(G_LED, OUTPUT);
  pinMode(Y_LED, OUTPUT);

  Serial.begin(9600); 
}

void loop() {
  sensor = analogRead(pin);                    // Reading the value from the LM35 sensor using the A0 ingress
  millivolts = (sensor / 1023.0) * 5000;       // Converting the value in a number that indicates the millivolts
  celsius = ((sensor * 0.00488) - 0.5) / 0.01; // Celsius value (10 mV for each degree, 0°=500mV)
  farhenheit = celsius * 1.8 + 32;             // Fahrenheit value
 
  lcd.setCursor(4, 2);                         // Set the cursor at the right of "mV="
  lcd.print(millivolts);                       // Print the mV value
  lcd.setCursor(4, 0);                         // Same here for °C and °F
  lcd.print(celsius);
  lcd.setCursor(4, 1);

  Serial.print(farhenheit);

  if (millivolts < 700) {    // Green LED is on when the temperature is under or equal to 20° 
  // if (celsius < 20) {     // Alternative
    analogWrite(G_LED, 255);
    analogWrite(Y_LED, 0); }
  else {
    analogWrite(G_LED, 0);
    analogWrite(Y_LED, 255); // Yellow LED is on when the temperature is above of 20°C
  }  
  delay(1000);
}

Answer 1

Fix - 我找不到错误，但我怀疑这是由于连接的奇怪布局造成的。您还尝试将光标设置为第 3 行，但您使用的 LCD 没有 3 行，它是 16x2 LCD.

我做了什么 - 所以我所做的是我重新做了整个项目，我连接了一个新的 LCD，这次用了数字对比度，这样它就可以动态改变的。我还确保包括您在上一个项目中使用的传感器。整个项目是一个 Arduino 控制 LCD 并输出华氏度和毫伏的温度。

这里是project link (Tinkercad).

代码：

#include <LiquidCrystal.h> 
// Adds the liquid crystal lib

int contrast = 40; // Set the contrast of the LCD
LiquidCrystal lcd (12, 11, 5, 4, 3, 2); // Instantiate the LCD

float fahrenheit;
float millivolts;

void setup ()
{
  analogWrite(6, contrast); // Wrjte the contrast to the LCD
  lcd.begin(16, 2); // Init the LCD
}

void loop ()
{
  int sensor = analogRead(0);
  millivolts = (sensor/1023.0)*5000;
  fahrenheit = (((sensor*0.00488)-0.5)/0.01)*1.8+32;
  
  lcd.setCursor(0, 0); 
  lcd.print("Temp(F):");
  lcd.setCursor(11, 0);
  lcd.print(fahrenheit);
  
  lcd.setCursor(0, 1);
  lcd.print("Volts(mV):");
  lcd.setCursor(12, 1);
  lcd.print(millivolts);
}

图表

LCD 在模拟环境中不工作

LCD doesn't work in a simulated enviroment

arduino

simulation

arduino-uno

arduino-c++

tinkercad